Public Sub UploadDirectoryContent(ByVal strPath As String, ByVal strExtension _
  As String)
 
    Dim strFile As String
    Dim varFile As Variant
    Dim strModus As String
    Dim colFiles As Collection
 
    If Right$(strPath, 1) <> "\" Then
        strPath = strPath & "\"
    End If
 
    If LCase$(strExtension) = "bmp" _
    Or LCase$(strExtension) = "gif" _
    Or LCase$(strExtension) = "jpg" _
    Or LCase$(strExtension) = "zip" _
    Or LCase$(strExtension) = "rar" Then
        strModus = "binary"
    Else
        strModus = "ascii"
    End If
 
    If Len(strExtension) = 0 Then
        strExtension = "*"
    End If
 
    strFile = Dir$(strPath & "*." & strExtension, vbNormal)
    If strFile = vbNullString Then
        MsgBox "Keine Dateien im Verzeichnis"
        Exit Sub
    End If
 
    Set colFiles = New Collection
    Do Until strFile = vbNullString
        colFiles.Add strPath & strFile
        strFile = Dir$()
    Loop
 
    Open "C:\FTP.TXT" For Output As #1
        Print #1, "open ftp.server.ext"
        Print #1, "USERNAME"            ' Username
        Print #1, "PASSWORD"            ' Password
        Print #1, "hash"                ' ByteStates
        Print #1, strModus              ' ASCII (Bilder und Archive = 'binary')
        For Each varFile In colFiles
            Print #1, "put """ & CStr(varFile) & """"
        Next varFile
        Print #1, "disconnect"          ' Disconnecting
        Print #1, "quit"                ' Quit ftp
        Print #1, "exit"                ' Exit shell
    Close #1
 
    Set colFiles = Nothing
 
    Shell "ftp -s:C:\FTP.TXT"
 
End Sub

Ohne Mampf, kein Kampf !