Public Declare Function GetDC Lib "User32" (ByVal hwnd As Long) _
      As Long
 
Public Declare Function DeleteObject Lib "gdi32" (ByVal hObject _
      As Long) As Long
 
Public Declare Function CreateRectRgn Lib "gdi32" (ByVal X1 _
      As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 _
      As Long) As Long
 
Public Declare Function CombineRgn Lib "gdi32" (ByVal hDestRgn _
      As Long, ByVal hSrcRgn1 As Long, ByVal hSrcRgn2 As Long, _
      ByVal nCombineMode As Long) As Long
 
Public Declare Function GetPixel Lib "gdi32" (ByVal hDC As Long, _
      ByVal x As Long, ByVal y As Long) As Long
 
Public Declare Function SetWindowRgn Lib "User32" (ByVal hwnd _
      As Long, ByVal hRgn As Long, ByVal bRedraw As Long) As Long
 
 
Public cmdDc As Long
 
Public Function picTranz(cpic As PictureBox) As Long
 Dim lHoch As Long
 Dim lBreit As Long
 Dim lTemp As Long
 Dim lSkin As Long
 Dim lStart As Long
 Dim lZeile As Long
 Dim lSpalte As Long
 Dim lBackColor As Long
 lSkin = CreateRectRgn(0, 0, 0, 0)
 With cpic
  lHoch = .Height / Screen.TwipsPerPixelY
  lBreit = .Width / Screen.TwipsPerPixelX
  lBackColor = GetPixel(.hDC, 0, 0)
  For lZeile = 0 To lHoch - 1
   lSpalte = 0
   Do While lSpalte < lBreit
    Do While lSpalte < lBreit And GetPixel(.hDC, lSpalte, lZeile) = lBackColor
     lSpalte = lSpalte + 1
    Loop
    If lSpalte < lBreit Then
     lStart = lSpalte
     Do While lSpalte < lBreit And GetPixel(.hDC, lSpalte, lZeile) <> lBackColor
      lSpalte = lSpalte + 1
     Loop
     If lSpalte > lBreit Then lSpalte = lBreit
      lTemp = CreateRectRgn(lStart, lZeile, lSpalte, lZeile + 1)
      Call CombineRgn(lSkin, lSkin, lTemp, 2)
      Call DeleteObject(lTemp)
     End If
   Loop
  Next lZeile
 End With
 picTranz = lSkin
End Function
 
Public Sub picTransparent(cpic As PictureBox)
 Dim lSkin As Long
 With cpic
  .Visible = True
  .BorderStyle = 0
  .AutoRedraw = True
  .AutoSize = True
  lSkin = picTranz(cpic)
  Call SetWindowRgn(cpic.hwnd, lSkin, True)
 End With
End Sub

_________________________________________________________
www.proofs-site.de.vu
Meine VB-Seite!