Public Function FindeEintraegeInDatei(ByRef sDateipfad As String, ByRef sSuche _
  As String, ByRef sSuche2 As String) As String()
Dim iTextdatei As Integer
Dim sTextZeile As String
Dim lStart As Long
Dim lEnde As Long
Dim lIdx as Long
 
 
lIdx = 0
'Wurde nichts gefunden ist der Rückgabewert ein Array mit nur dem Element 0
Redim FindeEintraegeInDatei(lIdx)
 
On Error GoTo end_function
 
'öffne Datei
iTextdatei = FreeFile
Open sDateipfad For Input As iTextdatei
 
'Schleife bis Datreiende
Do While Not EOF(iTextdatei)
    'Lese eine Zeile aus Datei
    Line Input #iTextdatei, sTextZeile
 
    'Suche Schlüsselwort, Anfürungsstriche werden im String durch "" dargestellt
    lStart = InStr(1, sTextZeile, sSuche & sSuche2)
 
    'Wurde Schlüsselwort gefunden?
    If lStart > 0 Then
        'Das Einlesen des gesuchten Wertes beginnt direkt nach dem Schlüsselwort
        lStart = lStart + Len(sSuche & sSuche2)
        'und endet vor dem nächsten Leerzeichen
        lEnde = InStr(lStart, sTextZeile, Chr(34))
        If lEnde > 0 Then
            'Gesuchten Wert in Array eintragen
            lIdx = lIdx + 1
            Redim Preserve FindeEintraegeInDatei(lIdx)
            FindeEintraegeInDatei(lIdx) = Mid(sTextZeile, lStart, lEnde - _
              lStart)
        End If
    End If
Loop
 
end_function:
    'schließe Datei
    Close #iTextdatei
End Function