' Hier die benötigten API-Deklarationen
Declare Function ShellExecute Lib "shell32.dll" _
  Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal lpOperation As String, _
  ByVal lpFile As String, _
  ByVal lpParameters As String, _
  ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long
 
' Die nachfolgende Prozedur startet das Standard-EMail
' Programm, öffnet das Fenster für "Neue Nachrichten"
' und trägt ggf. die Empfängeradresse, den Betreff und
' den Nachrichtentext ein.
'
' Anm.:
'  Weitere Mailparameter wie zum Beispiel cc oder bcc sind denkbar,
' sind hier jedoch nicht implementiert.
' (Näheres siehe Dokument "SelfHTML 8.0", mailto: - Parameter)
 
'Ergänzung: hWnd ... -1, dann ist kein ME erforderlich
 
Public Sub StartEMail(ByVal hWnd As Long, _
  Optional ByVal Empfänger As String = "", _
  Optional ByVal Betreff As String = "", _
  Optional ByVal Text As String)
 
 
  ' hWnd: Fenster-Handle eines Formulars
  '       Ihrer Anwendung
  '-1... kein Fenster
  ' Empfänger: EMail-Adresse des Empfängers (opt.)
  ' Betreff: EMail-Betreff (optional)
  ' Text: EMail-Text (Optional)
 
  ' Hier werden die Mail-Parameter gespeichert
  Dim Mailparameter As String
  Mailparameter = ""
 
  ' Wurde ein Betreff angegeben?
  If Betreff <> "" Then
    AddMailParam Mailparameter, "subject=" & Betreff
  End If
 
  ' Wurde ein Text angegeben?
  If Text <> "" Then
    AddMailParam Mailparameter, "body=" & Text
  End If
 
  Screen.MousePointer = 11
  Call ShellExecute(hWnd, "Open", "mailto:" & _
    Empfänger & Mailparameter, "", "", 1)
  Screen.MousePointer = 0
End Sub
 
Private Sub AddMailParam(ByRef r_AllParams As String, _
  ByVal p_Param As String)
 
  If r_AllParams = "" Then
    r_AllParams = "?" & p_Param
  Else
    r_AllParams = r_AllParams & "&" & p_Param
  End If
End Sub
 
'Beispiel:
'StartEMail Me.hWnd, "tipps@vbarchiv.de", "Neue Tipps", "Hier ein Tipp für das" & _
  "vb@rchiv..."

Visual Basic 6.0 Grundkenntnisse und ansonsten alles rund um AutoCAD