Private Sub Command1_Click()
  Dim oObject     As Object
  Dim oControl    As Control
  Dim sName       As String
 
  Set oObject = GetControl(Me, "List1")
  If Not oObject Is Nothing Then
    ' Ok ein Control ODER eine Auflistung von Controlls
    ' mit diesem Namen existiert.
    ' Nun müssen wir nur wissen um was es sich handelt
    On Error Resume Next
    ' Welches Attribut hat jedes Control ? Genau
    ' einen Namen. Also wenn wir hier einen Fehler
    ' bekommen, dann muss es wohl eine Auflistung von
    ' Controls sein.
    sName = oObject.name
    If Err = 0 Then
      ' Ein einzelnes Control
      On Error GoTo 0
      Set oControl = oObject
      MsgBox oControl.name
      ' So kann man z.B. feststellen was für Control das
      ' denn eigentlich ist
      If TypeOf oControl Is TextBox Then
        Debug.Print "Eine TextBox"
      ElseIf TypeOf oControl Is ListBox Then
        Debug.Print "Eine ListBox"
      ElseIf TypeOf oControl Is ComboBox Then
        Debug.Print "Eine ComboBox"
      End If
    Else
      ' Eine Auflistung von Controls
      Err.Clear
      On Error GoTo 0
      For Each oControl In oObject
        sName = sName & oControl.name & vbCrLf
      Next oControl
      MsgBox "Gleich mehrere : " & vbCrLf & sName
      ' Oder z.B.
      MsgBox oObject(0).name
    End If
  End If
 
End Sub
 
Public Function GetControl(oForm As Form, _
                            sControllName As String) As Object
  Dim oControl    As Object
 
  On Error GoTo Error_
  Set GetControl = oForm.Controls(sControllName)
  Exit Function
Error_:
  GetControl = Nothing
End Function