Option Explicit
 
Private Sub Form_Load()
 
    Dim e As Double
 
    e = GetDistance(46.999913, 15.492768, 47.000023, 15.492642)
 
 
End Sub
 
Public Function GetDistance _
    (Latitude1 As Double, _
    Longitude1 As Double, _
    Latitude2 As Double, _
    Longitude2 As Double _
    ) As Double
 
    Dim Lat1 As Double
    Dim Lat2 As Double
    Dim Lon1 As Double
    Dim Lon2 As Double
 
    Lat1 = Deg2Rad(Latitude1)
    Lat2 = Deg2Rad(Latitude2)
    Lon1 = Deg2Rad(Longitude1)
    Lon2 = Deg2Rad(Longitude2)
 
    GetDistance = _
    ArcCos(Sin(Lat1) * Sin(Lat2) _
    + Cos(Lat1) * Cos(Lat2) _
    * Cos(Lon2 - Lon1)) * 6378.388
End Function
 
Public Function DezimalGrad _
    (Grad As Double, _
    Min As Double, _
    Sec As Double _
    ) As Double
 
    DezimalGrad = Grad + Min / 60 + Sec / 3600
End Function
 
Public Function ArcCos(X As Double) As Double
    ArcCos = Atn(-X / Sqr(-X * X + 1)) + 2 * Atn(1)
End Function
 
Public Function Deg2Rad _
    (AngleDegrees As Double) As Double
 
    Deg2Rad = AngleDegrees * Pi / 180
End Function
 
Public Function Pi() As Double
    Pi = 4 * Atn(1)
End Function