Option Explicit
 
Dim pic As PictureBox  'Bild
Dim picsel As PictureBox 'zu suchender Ausschnitt
 
 
Private Sub Form_Load()
 
   Set pic = Me.Controls.Add("VB.PictureBox", "pb")
   Set picsel = Me.Controls.Add("VB.PictureBox", "pbsel")
   pb_param pic
   pb_param picsel
 
   'Hier ein Bild laden
   pic.Picture = LoadPicture("C:\daten\test.jpg")
 
   picsel.Top = pic.Top + pic.Height + 5
 
   'Ausschnitt der Größe 80*100 Pixel 
   picsel.Width = 80 * 15: picsel.Height = 100 * 15
 
   'Ausschnitt erstellen (ab Position 150, 100)  
   picsel.PaintPicture pic.Picture, 0, 0, 80, 100, 150, 100, 80, 100
 
   Me.Height = pic.Height + picsel.Height + 500
 
   'Suche nach der Position des Ausschnitts (ggf. linke obere Ecke)
   Dim x%, y%
   FindSelection x, y 'Hier sollten 150/100 gefunden werden
 
End Sub
 
 
Private Sub pb_param(pbox As PictureBox)
  With pbox
    .Visible = True: .AutoSize = True: .AutoRedraw = True:
    .ScaleMode = vbPixels: .BorderStyle = vbBSNone
  End With
End Sub
 
 
Private Sub FindSelection(ByRef x%, ByRef y%)
 
   Dim i%, k%, l%, m%, l1%, m1%, id As Boolean
 
   x = -1: y = -1 'Init.
 
   'Bildschleife 
   For i = 0 To pic.ScaleHeight - picsel.ScaleHeight
      For k = 0 To pic.ScaleWidth - picsel.ScaleWidth
         id = True
         'Schleife über Bildausschnitt      
         For l = 0 To picsel.ScaleHeight - 1
            l1 = l + i
            For m = 0 To picsel.ScaleWidth - 1
               m1 = m + k
               If pic.Point(m1, l1) <> picsel.Point(m, l) Then
                  'Abbruch bei Abweichung
                  id = False: GoTo nextpos
               End If
            Next m
         Next l
nextpos:
         If id Then x = i: y = k: Exit Sub 'Ausschnitt gefunden
     Next k
  Next i
End Sub