Option Explicit
 
Dim lLastStart      As Long
Dim lLastLength     As Long
Dim lCurrLineStart  As Long
Dim lTemp           As Long
 
Private Sub RichTextBox1_KeyDown(KeyCode As Integer, Shift As Integer)
  Select Case KeyCode
    Case vbKeyUp, vbKeyDown, vbKeyLeft, vbKeyRight
      StoreLine
    Case Else
  End Select
End Sub
Private Sub RichTextBox1_KeyUp(KeyCode As Integer, Shift As Integer)
  MarkLine
End Sub
 
Private Sub RichTextBox1_MouseDown(Button As Integer, _
  Shift As Integer, X As Single, y As Single)
  StoreLine
End Sub
Private Sub RichTextBox1_MouseUp(Button As Integer, _
  Shift As Integer, X As Single, y As Single)
  MarkLine
End Sub
 
Private Sub StoreLine()
  ' Die letzte Zeile merken
  With RichTextBox1
    If .SelStart > 0 Then
      lLastStart = InStrRev(.Text, vbCrLf, .SelStart, vbTextCompare)
      lTemp = InStr(.SelStart, .Text, vbCrLf, vbTextCompare)
    Else
      lLastStart = 0
      lTemp = InStr(.SelStart + 1, .Text, vbCrLf, vbTextCompare)
    End If
    If lTemp = 0 Then lTemp = Len(.Text) + 1
    lLastLength = lTemp - lLastStart
  End With
End Sub
 
Private Sub MarkLine()
  ' Wenn sich die Zeile geändert hat, die letzte Zeile markieren
  Dim lCurrStart      As Long
  Dim lCurrLength     As Long
 
  lTemp = 0
  With RichTextBox1
    If .SelStart > 0 Then lTemp = InStrRev(.Text, vbCrLf, .SelStart, _
      vbTextCompare)
    If lCurrLineStart = lTemp Then
      ' dann wurde nur die Zeile nochmals selektiert
      Exit Sub
    End If
    ' aktuelle Selektion sichern
    lCurrStart = .SelStart
    lCurrLength = .SelLength
    lCurrLineStart = lTemp
    ' den gesamten Text schwarz einfärben
    .SelStart = 0
    .SelLength = Len(.Text)
    .SelColor = vbBlack
    ' letzte selektierte Zeile selektieren und Farbe ändern
    .SelStart = lLastStart
    .SelLength = lLastLength
    .SelColor = vbRed
    ' aktuelle Selektion zurücksetzten
    .SelStart = lCurrStart
    .SelLength = lCurrLength
  End With
End Sub