Public Class frmBilderListe
 
    'Hier eine Datei zum Speichern der gewählten Bilder angeben
    Const filelist As String = _
    "F:\Daten\Bilderliste.txt"  'Liste der Dateinamen
 
    Dim WithEvents cbofiles As New ComboBox With _
        {.Parent = Me}     'Liste der Bilddateien im Ordner
 
    Dim dt As New DataTable
    Dim dgv As New DataGridView With _
     {.Parent = Me, .DataSource = dt, _
      .AllowUserToAddRows = False, .Top = 50, .ReadOnly = True}
 
    Dim fbd As New FolderBrowserDialog With _
         {.Description = "Ordner mit Bilddateien angeben", _
          .ShowNewFolderButton = False}
 
    Private Sub frmBilderListe_FormClosing(ByVal sender As Object, _
        ByVal e As System.Windows.Forms.FormClosingEventArgs) _
        Handles Me.FormClosing
 
        If e.CloseReason = CloseReason.UserClosing Then
            If MsgBox("Wirklich beenden? ", _
                MsgBoxStyle.OkCancel) = MsgBoxResult.Cancel Then
                e.Cancel = True
            End If
        End If
 
        'Dateiliste speichern
        If dt.Rows.Count > 0 Then
            Dim fl(dt.Rows.Count - 1) As String
            For i As Integer = 0 To dt.Rows.Count - 1
                fl(i) = CStr(dt.Rows(i).Item(0))
            Next i
 
            IO.File.WriteAllLines _
            (filelist, fl, System.Text.Encoding.UTF8)
        End If
 
    End Sub
 
    Private Sub frmBilderListe_Load(ByVal sender As System.Object, _
                            ByVal e As System.EventArgs) Handles MyBase.Load
 
        dt.Columns.Add("Datei", GetType(String))
        dt.Columns.Add("Bild", GetType(Bitmap))
 
        'Dateiliste und zugehörige Bilder laden
        If IO.File.Exists(filelist) Then
            Dim files() As String = _
            IO.File.ReadAllLines(filelist, System.Text.Encoding.UTF8)
            For i As Integer = 0 To files.Count - 1
                If IO.File.Exists(files(i)) Then
                    Dim bmp As New Bitmap(files(i))
                    dt.Rows.Add(files(i), bmp)
                End If
            Next i
        End If
 
        'Ordner mit Bilddateien auswählen
        If fbd.ShowDialog = DialogResult.OK Then
            For Each file As String In IO.Directory.GetFiles _
                (fbd.SelectedPath, "*.jpg", _
                IO.SearchOption.TopDirectoryOnly)
                cbofiles.Items.Add(file)
            Next file
        End If
 
    End Sub
 
    Private Sub cbofiles_SelectedIndexChanged(ByVal sender As Object, _
        ByVal e As System.EventArgs) Handles cbofiles.SelectedIndexChanged
 
        'Neue Zeile an Tafel anhängen gemäß Auswahl in der Combobox
        Dim bmp As New Bitmap(cbofiles.SelectedItem.ToString)
        dt.Rows.Add(CStr(cbofiles.SelectedItem), bmp)
    End Sub
 
End Class