Public Function FindColorPosition(ByVal bmp As Bitmap, _
                                      ByVal colortofind As Drawing.Color) As _
                                      Point
 
        If bmp.PixelFormat <> Imaging.PixelFormat.Format24bppRgb Then
            Throw New ArgumentException("Format not supported")
        End If
 
        Dim colorposition As New Point(-1, -1)
 
        Dim searchrect As Rectangle = New Rectangle(0, 0, bmp.Width, bmp.Height)
 
        ' Bilddaten (ggf. Ausschnitt) im Speicher sperren
        Dim bmp_data As Drawing.Imaging.BitmapData = _
          bmp.LockBits(searchrect, Drawing.Imaging.ImageLockMode.ReadWrite, _
          bmp.PixelFormat)
 
        ' Adresse des Beginns der Bitmap-Bilddaten ermitteln
        Dim bmp_ptr As IntPtr = bmp_data.Scan0
        ' tatsächliche Breite des Bildes
        Dim str As Integer = bmp_data.Stride
        If str <> bmp.Width * 3 Then
            bmp.UnlockBits(bmp_data)
            Throw New ArgumentException("Bitmap-Width not supported")
        End If
 
        ' Array für Bitmapdaten in geeigneter Größe erstellen
        ' (24-Bit-Bitmap: 3 Byte / Pixel in Bildbreite)
        Dim bmp_bytes As Integer = bmp.Width * bmp.Height * 3
 
        ' Null-basiertes Byte-Array (muss eindimensional sein)
        ' in der erforderlichen Größe vereinbaren
        Dim bmp_array(0 To bmp_bytes - 1) As Byte
 
        ' Die Bitmapdaten in das Array kopieren
        Runtime.InteropServices.Marshal.Copy(bmp_ptr, bmp_array, 0, bmp_bytes)
        Dim byte_index As Integer = -3, endloop As Boolean? = False
        With colortofind ' Die Bilddaten bearbeiten
            ' (Doppelschleife mit y-x-pixelbezogenem Zugriff 
            ' auf die Daten im Array)
            For y As Integer = 0 To bmp.Height - 1
                For x As Integer = 0 To bmp.Width - 1
                    ' Array-Index für x,y-BytePosition, 
                    byte_index += 3
 
                    'Hier Farbbyte-Reihenfolge B/G/R oder R/G/B nutzen
                    If bmp_array(byte_index) = .B And _
                       bmp_array(byte_index + 1) = .G And _
                       bmp_array(byte_index + 2) = .R Then
                        colorposition.X = x
                        colorposition.Y = y
                        endloop = True
                        Exit For
                    End If
                Next x
                If endloop Then Exit For
            Next y
        End With
 
        ' Die gesperrten Bilddaten freigeben
        bmp.UnlockBits(bmp_data)
 
        Return colorposition
    End Function