'Modul
Option Explicit
Private Declare Function sndPlaySound Lib "winmm.dll" Alias  "sndPlaySoundA" ( _
  ByVal lpszSoundName As String,  ByVal uFlags As Long) As Long
Private Const SND_ASYNC = &H1
Private Const SND_LOOP = &H8
Private Const SND_SYN = &H0
Private Declare Function mciSendString Lib "winmm.dll" _
  Alias "mciSendStringA" (ByVal lpszCommand As String, _
  ByVal lpszReturnString As String, _
  ByVal cchReturnLength As Long, _
  ByVal hwndCallback As Long) As Long
 
Private Declare Function GetShortPathName Lib "kernel32" _
  Alias "GetShortPathNameA" (ByVal lpszLongPath As String, _
  ByVal lpszShortPath As String, _
  ByVal cchBuffer As Long) As Long
 
Public Function MP3_Play(ByVal sFile As String, _
  ByVal sAlias As String) As Boolean
 
  Dim bResult As Boolean
 
  ' Dateinamen in DOS 8.3 Format, da z.B. Sonderzeichen
  ' wie Leerzeichen Probleme machen
  Dim sBuffer As String
  Dim lResult As Long
 
  sBuffer = Space$(255)
  lResult = GetShortPathName(sFile, sBuffer, Len(sBuffer))
 
  If lResult <> 0 Then
    sFile = Left$(sBuffer, InStr(sBuffer, vbNullChar) - 1)
 
    ' MCI öffnen
    lResult = mciSendString("open " & sFile & _
      " type MPEGVideo alias " & sAlias, 0, 0, 0)
 
    If lResult = 0 Then
      ' MP3 abspielen
      If mciSendString("play " & sAlias & _
        " from 0", 0, 0, 0) = 0 Then      
        bResult = True
      End If
    End If
  End If
 
  MP3_Play = bResult
End Function
 
Public Sub MP3_Stop(ByVal sAlias As String)
  mciSendString "stop " & sAlias, 0, 0, 0
  mciSendString "close " & sAlias, 0, 0, 0
End Sub
 
Public Sub PlaySound(sFileName as String)
Call sndPlaySound(sFileName, SND_LOOP)
End Sub
'Modul ende
'Form 
Private Sub NewMail()
'bei einer mp3-Datei:
Call MP3_Play("C:\sound.mp3","MP3_1")
'bei einer wav:
Call playSound("C:\sound.wav")
End Sub
 
Private Sub cmdOK_Click
PlaySound ""
MP3_STOP "MP3_1"
End Sub