<code><font color=green>' Inhalte der Controls speichern</font>
Private Sub Command1_Click()
  Dim Ctl As Control
  Dim x As String
  Dim value As String
 
  <font color=green>' Ini-Datei</font>
  Const IniFile = "f:\test.ini"
 
  <font color=green>' Alle Controls der aktuellen Form durchlaufen</font>
  For Each Ctl In Me.Controls
    With Ctl
      x = .Name
 
      <font color=green>' Prüfen, ob Steuerelementfeld (Array)</font>
      On Local Error Resume Next
      x = x & "(" & CStr(.Index) & ")"
      On Local Error GoTo 0
    End With
 
    value = vbNullString
 
    If TypeOf Ctl Is TextBox Then
      <font color=green>' TextBox</font>
      value = Ctl.Text
    ElseIf TypeOf Ctl Is HScrollBar Or TypeOf Ctl Is VScrollBar Then
      <font color=green>' horiz./vertik. Scrollbar</font>
      value = CStr(Ctl.value)
    ElseIf TypeOf Ctl Is OptionButton Or TypeOf Ctl Is CheckBox Then
      <font color=green>' OptionButton/CheckBox</font>
      value = CStr(Ctl.value)
    Else
      <font color=green>' usw.</font>
    End If
 
    <font color=green>' Inhalt/Wert speichern</font>
    If value <> vbNullString Then
      WritePrivateProfileString "Controls", x, value, IniFile
    End If
  Next
End Sub
 
 
<font color=green>' Inhalte der Controls lesen</font>
Private Sub Command2_Click()
  Dim Ctl As Control
  Dim x As String
  Dim value As String
  Dim lRet As Long
 
  <font color=green>' Ini-Datei</font>
  Const IniFile = "f:\test.ini"
 
  <font color=green>' Alle Controls der aktuellen Form durchlaufen</font>
  For Each Ctl In Me.Controls
    With Ctl
      x = .Name
 
      <font color=green>' Prüfen, ob Steuerelementfeld (Array)</font>
      On Local Error Resume Next
      x = x & "(" & CStr(.Index) & ")"
      On Local Error GoTo 0
    End With
 
    value = Space$(256)
    lRet = GetPrivateProfileString("Controls", x, vbNullString, _
      value, Len(value), IniFile)
    If lRet <> 0 Then
      value = Left$(value, lRet)
      If TypeOf Ctl Is TextBox Then
        <font color=green>' TextBox</font>
        Ctl.Text = value
      ElseIf TypeOf Ctl Is HScrollBar Or TypeOf Ctl Is VScrollBar Then
        <font color=green>' horiz./vertik. Scrollbar</font>
        Ctl.value = CInt(value)
      ElseIf TypeOf Ctl Is OptionButton Then
        <font color=green>' OptionButton</font>
        Ctl.value = CBool(value)
      ElseIf TypeOf Ctl Is CheckBox Then
        <font color=green>' CheckBox</font>
        Ctl.value = CInt(value)
      Else
        <font color=green>' usw.</font>
      End If
    End If
  Next
End Sub</code>