Private Sub cmdListView_Click()
  Dim oCon          As New ADODB.Connection
  Dim oRecordset    As ADODB.Recordset
  Dim oField        As ADODB.Field
  Dim oItem         As ListItem
  ' ersteinmal brauche wir ein Recordset
  With oCon ' Die Connection zur Datenbank
    .Provider = "Microsoft.Jet.OLEDB.3.51"
    .Open App.Path & "Test1.mdb"       ' Pfad & Name der Datenbank
    .CursorLocation = adUseClient
  End With
 
  Set oRecordset = New ADODB.Recordset
  oRecordset.Open "Select * from tblFileList", oCon, adOpenForwardOnly, _
    adLockReadOnly, 0
 
  ' Sicherstellen, das das ListView leer ist
  ListView1.ColumnHeaders.Clear
  ListView1.ListItems.Clear
 
  ListView1.View = lvwReport
  ' Hier richten wir das ListView ein
  For Each oField In oRecordset.Fields
    ' jedes Feld aus dem Recordset als Überschrift in das ListView
    ListView1.ColumnHeaders.Add , oField.Name, oField.Name
  Next
  'Nun das Recordset durchlaufen und alle Daten in das ListView
  oRecordset.MoveFirst
  Do
    ' ein ListItem mit dem ersten Feld des aktuellen Recordseteintrages erzeugen
    For Each oField In oRecordset.Fields
      If oItem Is Nothing Then
        ' ein neues ListItem erzeugen
        Set oItem = ListView1.ListItems.Add(, , oField.Value)
      Else
        oItem.SubItems(ListView1.ColumnHeaders.Item(oField.Name).Index - 1) = _
          IIf(Not IsNull(oField.Value), oField.Value, "")
      End If
    Next
    Set oItem = Nothing ' Unser ListItem wieder auf Nothing setzten
    ' nächsten Datensatz aus dem Recordset
    oRecordset.MoveNext
    If oRecordset.EOF Then Exit Do ' Wenn EOF, dann sind wir am Ende angekommen
  Loop
  Set oField = Nothing
  Set oCon = Nothing
  Set oRecordset = Nothing
End Sub