Private Function GetErrorsInWeeks(year As Integer, masch As Integer, _
                             mininterval As Integer) As DataTable
 
    Dim cal As Globalization.Calendar = _
    Globalization.CultureInfo.CurrentCulture.Calendar
 
    Dim q = From row As DataRow In dt.AsEnumerable
      Where IsFullRow(row) AndAlso _
        row.Field(Of Date)("Störung Zeit").Year = year
        Let wk As Integer = _
              cal.GetWeekOfYear(row.Field(Of Date)("Störung Zeit"), _
              Globalization.CalendarWeekRule.FirstDay, DayOfWeek.Monday), _
        art As String = row.Field(Of String)("Störung Art"), _
        minint As Boolean = _
            row.Field(Of Integer)("Störung Dauer") >= mininterval
      Group By wk, art, minint Into Count()
      Order By wk, art, minint
 
    Dim df As New DataTable
    With df.Columns
       .Add("Woche in " & year.ToString)
       .Add("Störung Art")
       .Add(mininterval.ToString & " Min. überschritten?", GetType(Boolean))
       .Add("Häufigkeit", GetType(Integer))
    End With
 
    For Each el In q
       df.Rows.Add(el.wk, el.art, el.minint, el.Count)
    Next el
    Return df
End Function
 
 
Private Function IsFullRow(row As DataRow) As Boolean
     'Filtert Zeilen mit fehlenden Werten
     For i As Integer = 0 To row.ItemArray.Length - 1
        If IsDBNull(row(i)) Then Return False
     Next i
     Return True
End Function