Private Sub pd_PrintPage(sender As System.Object, _
   e As System.Drawing.Printing.PrintPageEventArgs) _
   Handles pd.PrintPage
 
   Static itemindex As Integer = 0  'fortlaufender lv-ItemIndex
 
   Dim pf As New Font("Arial", 6) 'Druckfont
 
   Dim linesperpage As Integer = _
       CInt(e.MarginBounds.Height / pf.GetHeight(e.Graphics)) - 1
   Dim fw As Integer = 80 'Spaltenbreite
 
   Dim lineindex As Integer = 0
   Dim ypos As Integer = e.MarginBounds.Top
 
   With e.Graphics
      Using br As New SolidBrush(Color.Black)
         'LV-Überschrift: Spaltenbezeichner
         For i As Integer = 0 To lv.Columns.Count - 1
            .DrawString(lv.Columns(i).Text, pf, br, _
                  e.MarginBounds.Left + i * fw, ypos)
         Next i
 
         'LV-Items in die aktuelle Druckseite eintragen
         While itemindex < lv.Items.Count And _
               lineindex < linesperpage
 
            ypos += CInt(pf.GetHeight(e.Graphics))
 
            For i As Integer = 0 To lv.Columns.Count - 1
               'auszugebender Text im Feld
               Dim text As String = _
                  lv.Items(itemindex).SubItems(i).Text
 
               'ggf. Formatierung der Nachkomma-Stellen
               If i = 2 Or i = 3 Then
                  text = Microsoft.VisualBasic.Format(CDbl(text), "0.0")
               End If
 
               Dim tl As Integer = 0
               'Text im Feld rechtsbündig ausrichten
               While tl < fw - 5
                  text = " " & text
                  tl = CInt(.MeasureString(text, pf).Width)
               End While
 
               .DrawString(text, pf, br, _
                       e.MarginBounds.Left + i * fw, ypos)
            Next i
 
            itemindex += 1
            lineindex += 1
         End While
 
         e.HasMorePages = itemindex < lv.Items.Count
      End Using
   End With
 
End Sub