Public Class frmDGVFormatNumber
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
 
    Dim WithEvents dgv As New DataGridView With 
        {.Parent = Me, .DataSource = bs,
        .Location = New Point(10, 10), .Size = New Drawing.Size(300, 300)}
 
 
    Private Sub frmDGVFormatNumber_Load(sender As Object, 
        e As EventArgs) Handles MyBase.Load
 
        'Testspalten
        With dt.Columns
            .Add("number (int)", GetType(Integer))
            .Add("number (dec)", GetType(Decimal))
            .Add("number (dbl)", GetType(Double))
        End With
 
        'zufällige Testdaten
        Dim dec As Decimal, dbl As Double
        Dim rndm As New Random(1234), g As Integer
        For i As Integer = 1 To 200
            g = rndm.Next(0, 5)
            dec = CDec(rndm.NextDouble)
            dec = CDec(dec * 10 ^ g)
            g = rndm.Next(0, 5)
            dbl = rndm.NextDouble
            dbl = dbl * 10 ^ g
            If rndm.NextDouble < 0.5 Then dbl *= -1
            dt.Rows.Add(i, dec, dbl)
        Next i
 
        'Datenbindung
        bs.DataSource = dt
 
        'Ausrichtung und Formatierung   
        For i As Integer = 0 To 2
            With dgv.Columns(i)
                .DefaultCellStyle.Alignment = 
                     DataGridViewContentAlignment.MiddleRight
 
                If .ValueType.Equals(GetType(Integer)) Then
                    .DefaultCellStyle.Format = "#####0"
                Else
                    .DefaultCellStyle.Format = "#####0.00000"
                End If
            End With
        Next i   
    End Sub
 
End Class