Option Explicit
Dim alf!          ' Drehwinkel
Dim si!, co!      ' Sinus und Kosinus
Dim sf%           ' Spiegelungsfaktor
Dim mf!           ' Maßstabsfaktor
Dim x0!, y0!      ' absolute Bezugskoordinaten
Dim dirFlg%       ' Richtungsflag
Const Pi = 3.1415 ' Konstante Pi
 
Private Sub Command1_Click() ' Vergrößern
 mf = mf + 10
End Sub
 
Private Sub Command2_Click() ' Verkleinern
 mf = mf - 10
End Sub
 
Private Sub Command3_Click() ' Spiegelung
 sf = -sf
End Sub
 
Private Sub Command4_Click() ' Richtungsänderung
 dirFlg = Not dirFlg
End Sub
 
Private Sub drawHouse() ' zeichnet Haus
 dwp 0, 10        ' Frontseite
 dwl 10, 10: dwl 10, 0: dwl 0, 0: dwl 0, 10
 dwp 1, 8         ' Fenster
 dwl 4, 8: dwl 4, 4: dwl 1, 4: dwl 1, 8
 dwp 6, 0         ' Tür
 dwl 6, 8: dwl 9, 8: dwl 9, 0: dwl 6, 0
 dwp -1, 9        ' Dachgiebel
 dwl 5, 15: dwl 11, 9
 dwc 5, 12, 1     ' Giebelfenster
 dwp 7, 13        ' Schornstein
 dwl 7, 16: dwl 9, 16: dwl 9, 11
End Sub
 
Private Sub dwc(dx1!, dy1!, R!) ' zeichnet relativen Kreis
Dim x1!, y1!
 dx1 = mf * dx1: dy1 = mf * dy1: R = mf * R
 x1 = x0 + dx1 * co - sf * dy1 * si: y1 = y0 - sf * dy1 * co - dx1 * si
 Circle (x1, y1), R
End Sub
 
Private Sub dwl(dx1!, dy1!) ' zeichnet relative Linie
Dim x1!, y1!
 dx1 = mf * dx1: dy1 = mf * dy1
 x1 = x0 + dx1 * co - sf * dy1 * si: y1 = y0 - sf * dy1 * co - dx1 * si
 Line -(x1, y1)
End Sub
 
Private Sub dwp(dx1!, dy1!) ' zeichnet relativen Punkt
Dim x1!, y1!
 dx1 = mf * dx1: dy1 = mf * dy1
 x1 = x0 + dx1 * co - sf * dy1 * si: y1 = y0 - sf * dy1 * co - dx1 * si
 PSet (x1, y1)
End Sub
 
Private Sub Form_Load()
 x0 = Width / 2: y0 = Height / 2
 alf = 0: sf = 1: mf = 200
End Sub
 
Private Sub Timer1_Timer() ' zeichnet Vektorgrafik
 Cls
 If dirFlg Then
  alf = alf + Pi / 100    ' im Uhrzeigersinn
 Else
  alf = alf - Pi / 100    ' entgegen Uhrzeigersinn
 End If
 si = Sin(alf): co = Cos(alf)
 Call drawHouse
End Sub