' Groesse der Hashtabelle
Private Const intTableSize As Integer = 11
' Eintraege, die in die Hashtabelle eingefuegt werden sollen
Dim MyItems As New Collection
 
' unsere Hashfunktion
' strText = Text, von dem der Hashwert zu ermitteln ist
' intFactor = Gewicht fuer den ersten Buchstaben
' intFactor2 = Gewicht fuer den dritten Buchstaben
Private Function CalcHash(ByVal strText As String, ByVal intFactor As Integer, _
    ByVal intFactor2 As Integer) As Integer
 
Dim intAsc1 As Integer, intAsc3 As Integer
intAsc1 = (Asc(Mid(strText, 1, 1)) - 64) * intFactor
intAsc3 = (Asc(Mid(strText, 3, 1)) - 64) * intFactor2
CalcHash = (intAsc1 + intAsc3) Mod intTableSize
End Function
 
Private Sub Command1_Click()
' "Hashtabelle" mit "Besetzt"-Markern
Dim bolOccupied(0 To intTableSize - 1) As Boolean
Dim intCurItem As Integer
Dim intFactor As Integer, intFactor2 As Integer, i As Integer
Dim intIndex As Integer
Dim bolCorrect As Boolean
For intFactor = 1 To 100
    For intFactor2 = 1 To 100
        ' "Besetzt"-Array zuruecksetzen
        For i = 0 To intTableSize - 1
            bolOccupied(i) = False
        Next
        ' Kollisionsfreiheit annehmen
        bolCorrect = True
        For intCurItem = 1 To MyItems.Count
            ' Hashwert ermitteln
            intIndex = CalcHash(MyItems(intCurItem), intFactor, intFactor2)
            ' auf Kollision pruefen
            If bolOccupied(intIndex) = False Then
                bolOccupied(intIndex) = True
            Else
                bolCorrect = False
                Exit For
            End If
        Next
        If bolCorrect Then
            ' keine Kollisionen
            MsgBox "Ermittelt: " & intFactor & ", " & intFactor2
            Exit Sub
        End If
    Next
Next
MsgBox "Nichts gefunden"
End Sub
 
Private Sub Form_Load()
MyItems.Add "CLA"
MyItems.Add "LEW"
MyItems.Add "SCH"
MyItems.Add "BUR"
MyItems.Add "GRI"
MyItems.Add "HAU"
MyItems.Add "KOM"
MyItems.Add "KRO"
MyItems.Add "PIN"
End Sub

Web: http://www.vbtricks.de.vu/

VBTricks.de.vu. Meine Webseite zu VB und anderen Programmiersprachen. Verschiedene fortgeschrittene OCXe und komplette Projekte sind im Sourcecode verf?gbar.