Structure PrototypeDaten
	Public Counter As Integer
	Public Traffic As Long
	Public StartTime As Date
	Public StopTime As Date
	Public Name As String
End Structure
 
Public DatenArray(100) As PrototypeDaten

Sub QuickSort_Name(ByVal StartIndex As Integer, ByVal EndeIndex As Integer)
' Startwerte für Sortierung des Bereichs festlegen
Dim i              As Integer = StartIndex
Dim j              As Integer = EndeIndex
Dim VergleichsWert As String  = DatenArray((StartIndex + EndeIndex) \ 2).Name
 
	' Schleife bis ZählerStart und ZählerEnde sich in der Mitte treffen
	Do While i <= j
		' nach dem größten Wert in der linken Hälfte des Bereichs suchen
		Do While DatenArray(i).Name < Vergleichswert
			i += 1
		Loop
		' nach dem kleinsten Wert in der rechten Hälte des Bereichs suchen
		Do While DatenArray(j).Name > Vergleichswert
			j -= 1
		Loop
		' ist i kleiner gleich j? (Links ist ein größerer Wert als Rechts)
		If i <= j Then
			' ja, also Datenfelder austauschen
			Swap(i, j)
			i += 1
			j -= 1
		End If
	Loop
 
	' ist der Beginn des Bereiches noch kleiner als j?
	If StartIndex < j Then
		' ja, also QSort mit neuem Bereich aufrufen (linke Hälfte)
		QuickSort_Name(StartIndex, j)
	End If
	' ist das Ende des Bereiches noch größer als i?
	If i < EndeIndex Then
		' ja, also QSort mit neuem Bereich aufrufen (rechte Hälfte)
		QuickSort_Name(i, EndeIndex)
	End If
End Sub ' QuickSort_Name