Option Explicit
 
 
Public Sub ShowCPUProperties()
 
 
 
  ' WMI-Objekte
  Dim objQuery  As Object, objField As Object
 
  ' Collection für CPU-Daten (es können ja mehrere CPU's vorhanden sein)
  Dim mCol As Collection, Data As CPUDatas
 
  ' Collection initialisieren
  Set mCol = New Collection
 
  ' WMI-Abfrage ausführen
  Set objQuery = GetObject("winmgmts:\\.\root\cimv2").ExecQuery( _
    "Select * from Win32_Processor")
 
  ' wenn irgendetwas gefunden wurde, dann weiter
  If Not objQuery Is Nothing Then
 
    ' objQuery enthält für jede CPU einen Eintrag
    For Each objField In objQuery
 
      ' wenn Daten vorhanden, dann weiter
      If Trim(objField.CurrentClockSpeed) <> "" Or Trim( _
        objField.Manufacturer) <> "" Then
 
        ' Data initialisieren bzw. neu machen
        Set Data = New CPUDatas
 
        ' Daten lesen
        With Data
          .CPUIndex = mCol.Count + 1
          .Speed = objField.CurrentClockSpeed & "MHz"
          .Manufacturer = objField.Manufacturer
        End With
 
        ' Data In Collection schreiben
        mCol.Add Data
 
      End If
 
    Next
 
  End If
 
  ' WMI-Objekte freigeben
  Set objField = Nothing
  Set objQuery = Nothing
 
  ' wenn nix gefunden wurde, dann Nachricht
  If mCol.Count = 0 Then
 
    MsgBox "Die Prozessordaten konnten nicht ermittelt werden."
 
  Else
 
    ' wurden Daten gefunden, dann ausgeben
    Dim I As Long
 
    For I = 1 To mCol.Count
      Set Data = mCol.Item(I)
 
      MsgBox "Hersteller: " & Data.Manufacturer & vbNewLine & "Taktfrequenz: " _
        & Data.Speed, , "Prozessor " & CStr(Data.CPUIndex)
    Next I
 
  End If
 
  ' Collection freigeben
  Set Data = Nothing
  Set mCol = Nothing
 
End Sub

----------------------------------
Wer fragt, kommt weiter!
----------------------------------