Private Sub Form_Load()
  ' Farben initialisieren
  InitColors
  InitColorCombo
End Sub
 
Private Sub InitColors()
  ' Farb-Auswahl erstellen
  Dim I As Long
  ReDim lColor(15) As Long
 
  lColor(0) = &HFFFFFF   ' Weiss
  lColor(1) = &HE0E0E0   ' Hellgrau
  lColor(2) = &H808080   ' Grau
  lColor(3) = &H0&       ' Schwarz
  lColor(4) = &HFF0000   ' Blau
  lColor(5) = &HFFFF00   ' Zyan (Türkis)
  lColor(6) = &HFF00&    ' Grün
  lColor(7) = &HFF00FF   ' Magenta
  lColor(8) = &HFF&      ' Rot
  lColor(9) = &HFFFF&    ' Gelb
  lColor(10) = &H800000  ' Dunkelblau
  lColor(11) = &H808000  ' Blaugrün
  lColor(12) = &H8000&   ' Dunkelgrün
  lColor(13) = &H800080  ' Violett
  lColor(14) = &H80&     ' Dunkelrot
  lColor(15) = &H8080&   ' Ocker
 
  ' PictureBox unsichtbar machen
  picColorX.Visible = False
 
  For I = 0 To UBound(lColor)
    With picColorX
      ' PictureBox mit der Farbe füllen
      .AutoRedraw = True
      .Cls
      picColorX.Line (0, 0)-(.ScaleWidth, .ScaleHeight), lColor(I), BF
 
      ' Jetzt noch einen Rahmen aussenrum
      picColorX.Line (0, 0)-(.ScaleWidth, .ScaleHeight), vbBlack, B
 
      ' und ab in die ImageList ;-)
      .Picture = .Image
      .AutoRedraw = False
 
      ImageList1.ListImages.Add , "H" & Hex$(lColor(I)), _
        .Picture
    End With
  Next I
End Sub
 
Private Sub InitColorCombo()
  ' ImageCombo mit den Farben füllen
  Dim I As Long
 
  ' zunächst alle Einträge löschen
  imgColorCombo.ComboItems.Clear
 
  ' jetzt die Abbildungsliste zuweisen
  imgColorCombo.ImageList = ImageList1
 
  ' und zu guter Letzt die Einträge erstellen
  For I = 1 To ImageList1.ListImages.Count
    With ImageList1.ListImages(I)
      imgColorCombo.ComboItems.Add , .Key, "", I, I
    End With
  Next I
End Sub
 
Private Sub imgColorCombo_Click()
  ' Farbewert ermitteln
  Dim lngColor As Long
 
  With imgColorCombo.SelectedItem
    lngColor = CLng("&" & .Key)
    'Anzeigen des aktuellen Farbwertes im Label1
    Label1.BackColor = lngColor
  End With
End Sub