| |
Fragen & Antworten rund um sev-Komponentenunsicher activex Steuerelemente | | | Autor: gus | Datum: 06.01.05 08:23 |
| Hallo zusammen,
nicht gerade ein Problem der sev-Komponenten, aber es tritt nun leider mit diesen auf, in diesem Falle sevEingabe (neueste Version und Version vom Juli getestet).
Ich habe jetzt auf 2 XP-Rechnern (Home und Professional) das Problem, das Word und orgAnice (Datenbank mit VBA) beim starten der Vorlagen, bzw. des Programmes folgenden MS-Hinweis bringt:
"Diese Anwendung versucht, möglicherweise unsichere ActiveX-Steuerelemente zu
initialisieren. Wenn die Datei aus einer vertrauenswürdigen Quelle stammt,
wählen Sie OK, und die Steuerelemente werden unter Verwendung der aktuellen
Arbeitsbereichseinstellungen initialisiert."
Der XP-Professional-PC lief vor einem halben Jahr ohne Probleme (dann ist nicht mehr mit den Programmen gearbeitet worden), der XP-Home ist nagelneu.
Ansonsten läuft die gleiche Konstellation auf weiteren 40 PC´s der Fa. ohne Probleme. Da es früher lief und jetzt Probleme gibt, kann es in meinen Augen nur ein Problem irgendwelcher Sicherheitseinstellungen nach irgendeinem MS-Patch sein.
In Google findet man nur einen Hinweis, das man in Word die Sicherheitsstufe runtersetzen soll (das funktioniert aber nicht), ansonsten soll man die Komponente mit einer Signatur versehen.
Hat jemand einen Lösungsvorschlag? oder Idee?
Gruß aus dem Norden
Guido Schlüter | |
Re: unsicher activex Steuerelemente | | | Autor: ClausGM | Datum: 26.01.05 10:25 |
| Hallo,
hast du da noch etwas herausgefunden, wie man diese Meldung wegbekommt?
Gruß
Claus Müller | |
Re: unsicher activex Steuerelemente | | | Autor: gus | Datum: 26.01.05 11:44 |
| Nein, leider nicht.
Signatur wäre Dieters Aufgabe, wobei ich nicht weiß, wie man ein OCX signieren kann, damit andere damit arbeiten können.
In orgAnice habe ich zwar eine VBA-Entwicklungsumgebung, aber keine Möglichkeit die Sicherheitsparameter zu ändern.
Es soll noch die Möglichkeit über Registry-Einträge geben, aber außer Andeutungen habe ich noch nichts rausgefunden.
Ich bin aber immer noch am suchen.
Gruß Guido Schlüter | |
Re: unsichere activex Steuerelemente | | | Autor: gus | Datum: 01.03.05 13:25 |
| Lösung gefunden.
Es liegt an der fm20.dll im Windows-System32-Verzeichnis.
Unter http://support.microsoft.com/kb/q214757/ kann man zumindestens einen Lösungshinweis sehen.
Ich habe mit einer "alten" Version die bestehende überschrieben (sichern nicht vergessen) und jetzt funktioniert wieder alles ohne Hinweise.
Gefunden habe ich eine "alte" Version in diversen Installationen von VB und VBA-Projekten.
Gruß Guido Schlüter | |
Re: unsichere activex Steuerelemente | | | Autor: ClausGM | Datum: 02.03.05 12:14 |
| Hallo,
vielen Dank. Das hilft auch bei meinem Problem, nämlich dem RTF-Control von Stephen Lebans (www.lebans.com).
Claus Müller | |
Re: unsichere activex Steuerelemente | | | Autor: visionauten | Datum: 14.09.07 06:56 |
| Hallo,
ich das gleiche Problem mit der sevCMd32 Komponente, Excel bringt immer diese Sicherheitswarnung! Die FM20.dll hab ich mittels Mircosoft Update auch schon aktualisiert! Einstellungen im Browser bringen nicht!
Wer hat einen Lösungsvorschlag!?!
DANKE DANKE | |
Re: unsicher activex Steuerelemente | | | Autor: ptahsoft | Datum: 25.09.07 11:34 |
| Hallo
ich wurde das Control wrappen. Eigenes UserControl darum bauen und diese mit dem notwendigen Interface für die Security versehen.
1. folgendes Modul erstellen und wichtig Main-Funktion initalisieren
Modul MObjSafe.bas
Option Explicit
Public Const IID_IDispatch = "{00020400-0000-0000-C000-000000000046}"
Public Const IID_IPersistStorage = _
"{0000010A-0000-0000-C000-000000000046}"
Public Const IID_IPersistStream = _
"{00000109-0000-0000-C000-000000000046}"
Public Const IID_IPersistPropertyBag = _
"{37D84F60-42CB-11CE-8135-00AA004BB851}"
Public Const INTERFACESAFE_FOR_UNTRUSTED_CALLER = &H1
Public Const INTERFACESAFE_FOR_UNTRUSTED_DATA = &H2
Public Const E_NOINTERFACE = &H80004002
Public Const E_FAIL = &H80004005
Public Const MAX_GUIDLEN = 40
Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(pDest As Any, pSource As Any, ByVal ByteLen As Long)
Public Declare Function StringFromGUID2 Lib "ole32.dll" (rguid As _
Any, ByVal lpstrClsId As Long, ByVal cbMax As Integer) As Long
Public Type udtGUID
data1 As Long
data2 As Integer
Data3 As Integer
Data4(7) As Byte
End Type
Public m_fSafeForScripting As Boolean
Public m_fSafeForInitializing As Boolean
Sub Main()
m_fSafeForScripting = True
m_fSafeForInitializing = True
End Sub ... den Rest siehe nächste Mail | |
Re: unsicher activex Steuerelemente | | | Autor: ptahsoft | Datum: 25.09.07 11:35 |
| Teil 2
Interface muss in das UserControl eingebaut werden
'//////////////////////////////////////////////////////////////////////////////
'//
'// IObjectSafety Interface Implementation
'//
'------------------------------------------------------------------------------
' IObjectSafety_GetInterfaceSafetyOptions
'------------------------------------------------------------------------------
Private Sub IObjectSafety_GetInterfaceSafetyOptions( _
ByVal riid As Long, _
pdwSupportedOptions As Long, _
pdwEnabledOptions As Long)
Dim Rc As Long
Dim rClsId As udtGUID
Dim IID As String
Dim bIID() As Byte
pdwSupportedOptions = INTERFACESAFE_FOR_UNTRUSTED_CALLER Or _
INTERFACESAFE_FOR_UNTRUSTED_DATA
If (riid <> 0) Then
CopyMemory rClsId, ByVal riid, Len(rClsId)
bIID = String$(MAX_GUIDLEN, 0)
Rc = StringFromGUID2(rClsId, VarPtr(bIID(0)), MAX_GUIDLEN)
Rc = InStr(1, bIID, vbNullChar) - 1
IID = left$(UCase(bIID), Rc)
Select Case IID
Case IID_IDispatch
pdwEnabledOptions = IIf(m_fSafeForScripting, _
INTERFACESAFE_FOR_UNTRUSTED_CALLER, 0)
Exit Sub
Case IID_IPersistStorage, IID_IPersistStream, _
IID_IPersistPropertyBag
pdwEnabledOptions = IIf(m_fSafeForInitializing, _
INTERFACESAFE_FOR_UNTRUSTED_DATA, 0)
Exit Sub
Case Else
Err.Raise E_NOINTERFACE
Exit Sub
End Select
End If
End Sub
'------------------------------------------------------------------------------
' IObjectSafety_SetInterfaceSafetyOptions
'------------------------------------------------------------------------------
Private Sub IObjectSafety_SetInterfaceSafetyOptions( _
ByVal riid As Long, _
ByVal dwOptionsSetMask As Long, _
ByVal dwEnabledOptions As Long)
Dim Rc As Long
Dim rClsId As udtGUID
Dim IID As String
Dim bIID() As Byte
If (riid <> 0) Then
CopyMemory rClsId, ByVal riid, Len(rClsId)
bIID = String$(MAX_GUIDLEN, 0)
Rc = StringFromGUID2(rClsId, VarPtr(bIID(0)), MAX_GUIDLEN)
Rc = InStr(1, bIID, vbNullChar) - 1
IID = left$(UCase(bIID), Rc)
Select Case IID
Case IID_IDispatch
If ((dwEnabledOptions And dwOptionsSetMask) <> _
INTERFACESAFE_FOR_UNTRUSTED_CALLER) Then
Err.Raise E_FAIL
Exit Sub
Else
If Not m_fSafeForScripting Then
Err.Raise E_FAIL
End If
Exit Sub
End If
Case IID_IPersistStorage, IID_IPersistStream, _
IID_IPersistPropertyBag
If ((dwEnabledOptions And dwOptionsSetMask) <> _
INTERFACESAFE_FOR_UNTRUSTED_DATA) Then
Err.Raise E_FAIL
Exit Sub
Else
If Not m_fSafeForInitializing Then
Err.Raise E_FAIL
End If
Exit Sub
End If
Case Else
Err.Raise E_NOINTERFACE
Exit Sub
End Select
End If
End Sub die notwendige TLB findest du unter
[url]http://www.ptahsoft.ch/test/OBJSAFE.zip[/url] Gruss
Ralf | |
Re: unsicher activex Steuerelemente | | | Autor: EgonF | Datum: 26.09.07 11:53 |
| Hierzu folgender link
http://support.microsoft.com/kb/827742
Gruß Egon | |
| Sie sind nicht angemeldet! Um auf diesen Beitrag zu antworten oder neue Beiträge schreiben zu können, müssen Sie sich zunächst anmelden.
Einloggen | Neu registrieren |
|
|
vb@rchiv CD Vol.6 vb@rchiv Vol.6
Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
Online-Update-Funktion Entwickler-Vollversionen u.v.m.Jetzt zugreifen Tipp des Monats sevZIP40 Pro DLL
Zippen und Unzippen wie die Profis!
Mit nur wenigen Zeilen Code statten Sie Ihre Anwendungen ab sofort mit schnellen Zip- und Unzip-Funktionen aus. Hierbei lassen sich entweder einzelnen Dateien oder auch gesamte Ordner zippen bzw. entpacken. Weitere Infos
|