Private Sub Irgendwas(sender As System.Object, e As System.EventArgs) Handles _
  CheckBox1.CheckedChanged, CheckBox2.CheckChanged, CheckBox3.CheckChanged
MessageBox.Show("Es ist was pasiert!")
End Sub

EALA FREYA FRESENA

Zitat:

ja diese Lösung kenne ich, ist das denn die einzigste? Muss ich 50x .checkChanged schreiben? Das gleucb ich nicht...aktuell habe ich einen Timer in Verwendung, aber gefällt mir auch net besonders gut. Hat jemand eine schönere Idee? Kann man denn nicht von der Klasse checkbox ableiten? aber wie?

Public Class frmEventHandlerDemo
 
    Private Checkboxes As New List(Of CheckBox)
 
 
    Private Sub CreateCheckboxes()
 
        Const Columns As Integer = 5
        Const Rows As Integer = 10
 
        Const CB_Width As Integer = 100
        Const CB_Height As Integer = 25
 
        For i As Integer = 1 To Columns
            For k As Integer = 1 To Rows
                Dim cb As New CheckBox With {.Parent = Me, _
                        .Width = CB_Width, .Height = CB_Height, _
                        .Left = i * CB_Width, .Top = k * CB_Height, _
                        .Text = "Box " & (Checkboxes.Count + 1).ToString, _
                        .Name = .Text}
 
                AddHandler cb.Click, AddressOf All_Checkboxes_Click
 
                Checkboxes.Add(cb)
            Next k
        Next i
 
    End Sub
 
 
 
    Private Sub All_Checkboxes_Click(ByVal sender As Object, _
                                     ByVal e As EventArgs)
 
        Dim cb As CheckBox = DirectCast(sender, CheckBox)
        MsgBox(cb.Text & " ist geclickt worden")
 
        Dim sum As Integer = 0, vl As Integer = 0
        For i As Integer = 0 To Checkboxes.Count - 1
            If Checkboxes(i).Tag IsNot Nothing AndAlso _
               Integer.TryParse(Checkboxes(i).Tag.ToString, vl) Then
                sum += vl
            End If
        Next i
 
    End Sub
 
 
    Private Sub frmEventHandlerDemo_Load(sender As System.Object, _
                    e As System.EventArgs) Handles MyBase.Load
 
        Me.Size = New Size(600, 400)
        CreateCheckboxes()
    End Sub
End Class

Sub HandlerAdder()
    Dim ctl As Control = Me.GetNextControl(Me, True)
    While Not ctl Is Nothing
        If TypeOf ctl Is CheckBox Then
            AddHandler TryCast(ctl, CheckBox).CheckedChanged, AddressOf _
              CheckBox_CheckedChanged
        End If
        ctl = Me.GetNextControl(ctl, True)
    End While
End Sub
 
Private Sub CheckBox_CheckedChanged(ByVal sender As System.Object, ByVal e As _
  System.EventArgs)
    MessageBox.Show(TryCast(sender, CheckBox).Text & " wurde geändert")
End Sub

Zitat:

Muss ich 50x .checkChanged schreiben?