Module xxxDataModule
 
    Public Class xxxDataClass
 
        'Datenquelle und Bindung
        Private _data As New DataSet
        Private WithEvents _binding As New BindingSource
 
        'Öffentliches Ereignis bei Positionswechsel in Tabelle
        Public Event RowPositionChanged() 
 
 
        Public Sub SelectData(ByVal SelectCommand As String)
 
            'Hier ein Dataset aus der Datenbank füllen
            'unter Nutzung des als Parameters übergebenen Select-Kommandos
 
            '.........
 
            'Statt dessen einige Testdaten per Code
            _data.Clear()
            _data.Tables.Add(New DataTable With {.TableName = "Testdaten"})
 
            With _data.Tables("Testdaten")
                .Columns.Add("Key", GetType(Integer))
                .Columns.Add("Date", GetType(DateTime))
                .Columns.Add("Text", GetType(String))
 
                For i As Integer = 1 To 100
                    .Rows.Add(i, Now.AddDays(i), "Satz " & i.ToString)
                Next i
            End With
 
            'Datenbindung
            _binding.DataSource = _data.Tables("Testdaten")
        End Sub
 
 
        Private Sub _binding_PositionChanged(sender As Object, e As EventArgs) _
            Handles _binding.PositionChanged
 
            RaiseEvent RowPositionChanged()  'Ereignis nach außen weiterreichen
        End Sub
 
 
        Public ReadOnly Property DataBinding() As BindingSource
            Get
                Return _binding 'Datenbindung abfragen
            End Get
        End Property
 
    End Class
 
 
    'Die öffentlich zugreifbare Instanz der Datenklasse
    Public Data As New xxxDataClass
 
End Module
 
 
 
Public Class xxxGUIForm
    Inherits System.Windows.Forms.Form
 
    Private Datagrid As New DataGridView
 
    Private Sub InitializeComponent()
        Me.SuspendLayout()
        '
        Me.ClientSize = New System.Drawing.Size(350, 500)
        Me.Name = "xxxGUI"
        Me.ResumeLayout(False)
 
        Datagrid.Parent = Me
 
    End Sub
 
    Private Sub xxxGUI_Load(sender As Object, 
                            e As EventArgs) Handles MyBase.Load
 
        InitializeComponent()
 
 
        With Datagrid
            .Dock = DockStyle.Fill
 
            'Control an Dateninstanz binden
            .DataSource = xxxDataModule.Data.DataBinding
        End With
 
    End Sub
End Class
 
 
 
Public Module xxxDataAccessModule
 
    Public Class xxxDataAccess
 
        Public Sub New()
            'Ereignishandler zuordnen
            AddHandler xxxDataModule.Data.RowPositionChanged, 
                       AddressOf rowpositionchanged
        End Sub
 
 
        Private Sub rowpositionchanged()
            Dim pos As Integer = xxxDataModule.Data.DataBinding.Position
            Console.WriteLine("Aktuelle Position: " & pos.ToString)
        End Sub
    End Class
 
    'Hier Datenverarbeitungs-Funktionen einbauen
    '......
End Module
 
 
 
Public Module xxxMain
 
    Public Sub main()
 
        'Dateninstanz füllen (Testdaten)
        xxxDataModule.Data.SelectData("xxxx")
 
        'Datenzugriffsklasse erstellen
        Dim DataAccess As New xxxDataAccess
 
        Using Gui As New xxxGUIForm
            Gui.ShowDialog()
        End Using
 
    End Sub
End Module