​Imports System.Runtime.InteropServices
Imports System.Text
Imports System.Windows.Automation
Public Class Form1
    <DllImport("user32.DLL")>
    Public Shared Function FindWindowEx(ByVal hwndParent As IntPtr, ByVal _
      hwndChildAfter As IntPtr, ByVal lpszClass As String, ByVal lpszWindow As _
      String) As IntPtr
    End Function
    <DllImport("user32.dll")>
    Public Shared Function EnumWindows(lpEnumFunc As EnumWindowsProc, lParam As _
      IntPtr) As <MarshalAs(UnmanagedType.Bool)> Boolean
    End Function
    Public Delegate Function EnumWindowsProc(hWnd As IntPtr, lParam As IntPtr) _
      As Boolean
    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
    Public Shared Function GetClassName(hWnd As IntPtr, lpClassName As _
      StringBuilder, nMaxCount As Integer) As Integer
    End Function
    Public Function GetDesktopHandle() As IntPtr
        Dim DesktopHandle As IntPtr = IntPtr.Zero
        EnumWindows(Function(WorkerW_Handle, OptionalParameter)
                        Dim HandleToString = New StringBuilder(256)
                        GetClassName(WorkerW_Handle, HandleToString, _
                          HandleToString.Capacity)
                        If HandleToString.ToString = "WorkerW" Or _
                        HandleToString.ToString = "Progman" Then
                            Dim Attachment_Folder As IntPtr = FindWindowEx( _
                            WorkerW_Handle, IntPtr.Zero, "SHELLDLL_DefView", _
                            Nothing)
                            If Attachment_Folder <> IntPtr.Zero Then
                                Dim Desktop_Folder As IntPtr = FindWindowEx( _
                                  Attachment_Folder, IntPtr.Zero, _
                                  "SysListView32", "FolderView")
                                If Desktop_Folder <> IntPtr.Zero Then
                                    DesktopHandle = Desktop_Folder
                                    Return False ' False bedeutet das der 
                                    ' Desktop gefnden wurde und die Suche 
                                    ' beendet ist.
                                End If
                            End If
                        End If
                        Return True ' Desktop wurde noch nicht gefunden. Die 
                        ' Suche fortsetzen.
                    End Function, IntPtr.Zero)
        Return DesktopHandle
    End Function
 
 
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles _
      Button1.Click
        Dim el As AutomationElement = AutomationElement.FromHandle( _
        GetDesktopHandle())
        Dim walker As TreeWalker = TreeWalker.ContentViewWalker
        Dim child As AutomationElement = walker.GetFirstChild(el)
        While child IsNot Nothing
            ListBox1.Items.Add(child.Current.Name)
            ' MsgBox(child.Current.ClassName)
            child = walker.GetNextSibling(child)
        End While
    End Sub
End Class

Imports System
Imports System.IO
Imports System.IO.Directory
 
'Verweis auf "Windows Script Host Object Model" (COM) setzen!
 
Public Class Form1
 
    Dim dtAusgabe As New DataTable
 
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) _
      Handles Button1.Click
 
        Dim File As String = ""
        Dim DesktopFolder As String = Environment.GetFolderPath( _
          Environment.SpecialFolder.DesktopDirectory)
 
        For Each File In System.IO.Directory.GetFiles(DesktopFolder, "*.lnk")
            EigenschaftenAuslesen(File)
        Next
 
        DataGridView1.DataSource = dtAusgabe
 
    End Sub
 
    Private Sub EigenschaftenAuslesen(ByVal File As String)
 
        Dim ShortCut As IWshRuntimeLibrary.IWshShortcut
 
        ShortCut = CType((New IWshRuntimeLibrary.WshShell).CreateShortcut( _
          File), IWshRuntimeLibrary.IWshShortcut)
 
        Dim NewRow As DataRow = dtAusgabe.NewRow
 
        With NewRow
            .Item("Link") = File
            .Item("AuszufuehrendeDatei") = ShortCut.TargetPath
            .Item("Arbeitsverzeichnis") = ShortCut.WorkingDirectory
            .Item("Beschreibung") = ShortCut.Description
            .Item("StartParameter") = ShortCut.Arguments
            .Item("HotKey") = ShortCut.Hotkey
        End With
 
        dtAusgabe.Rows.Add(NewRow)
 
    End Sub
 
    Private Sub dtPlanInitialisieren()
 
        dtAusgabe.TableName = "Datenausgabe"
 
        Dim keys(1) As DataColumn
        Dim column As New DataColumn
        column.DataType = System.Type.GetType("System.Int32")
        With column
            .ColumnName = "ID"
            .AutoIncrement = True
            .AutoIncrementStep = 1
        End With
        dtAusgabe.Columns.Add(column)
        keys(0) = column
        dtAusgabe.PrimaryKey = keys
 
        column = New DataColumn
        column.DataType = System.Type.GetType("System.String")
        column.ColumnName = "Link"
        dtAusgabe.Columns.Add(column)
 
        column = New DataColumn
        column.DataType = System.Type.GetType("System.String")
        column.ColumnName = "AuszufuehrendeDatei"
        dtAusgabe.Columns.Add(column)
 
        column = New DataColumn
        column.DataType = System.Type.GetType("System.String")
        column.ColumnName = "Arbeitsverzeichnis"
        dtAusgabe.Columns.Add(column)
 
        column = New DataColumn
        column.DataType = System.Type.GetType("System.String")
        column.ColumnName = "Beschreibung"
        dtAusgabe.Columns.Add(column)
 
        column = New DataColumn
        column.DataType = System.Type.GetType("System.String")
        column.ColumnName = "StartParameter"
        dtAusgabe.Columns.Add(column)
 
        column = New DataColumn
        column.DataType = System.Type.GetType("System.String")
        column.ColumnName = "HotKey"
        dtAusgabe.Columns.Add(column)
 
    End Sub
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) _
      Handles MyBase.Load
        dtPlanInitialisieren()
    End Sub
End Class

EALA FREYA FRESENA

Beitrag wurde zuletzt am 20.09.19 um 11:45:20 editiert.