mfg
rt

  Private oStringFormat As StringFormat
    Private oStringFormatComboBox As StringFormat
    Private oButton As Button
    Private oCheckbox As CheckBox
    Private oComboBox As ComboBox
 
    Private nTotalWidth As Int16
    Private nRowPos As Int16
    Private NewPage As Boolean
    Private nPageNo As Int16
    Private Header As String
    Private sUserName As String
    Private ÜSchriftart As New System.Drawing.Font("Arial", 12.0!, _
      System.Drawing.FontStyle.Regular, System.Drawing.GraphicsUnit.Point, _
      CType(0, Byte))
    Private ESchriftart As New System.Drawing.Font("Arial", 8.0!, _
    System.Drawing.FontStyle.Regular, System.Drawing.GraphicsUnit.Point, CType( _
    0, Byte))
 
 
    Private Sub PrintDocument1_BeginPrint(ByVal sender As Object, ByVal e As _
      System.Drawing.Printing.PrintEventArgs) Handles PrintDocument1.BeginPrint
        oStringFormat = New StringFormat
        oStringFormat.Alignment = StringAlignment.Near
        oStringFormat.LineAlignment = StringAlignment.Center
        oStringFormat.Trimming = StringTrimming.EllipsisCharacter
 
        oStringFormatComboBox = New StringFormat
        oStringFormatComboBox.LineAlignment = StringAlignment.Center
        oStringFormatComboBox.FormatFlags = StringFormatFlags.NoWrap
        oStringFormatComboBox.Trimming = StringTrimming.EllipsisCharacter
 
        oButton = New Button
        oCheckbox = New CheckBox
        oComboBox = New ComboBox
 
        nTotalWidth = 0
        For Each oColumn As DataGridViewColumn In Grid1.Columns
            nTotalWidth += oColumn.Width
        Next
 
        nPageNo = 1
        NewPage = True
        nRowPos = 0
    End Sub

    Private Sub PrintDocument1_PrintPage(ByVal sender As Object, ByVal e As _
      System.Drawing.Printing.PrintPageEventArgs) Handles _
      PrintDocument1.PrintPage
        Static oColumnLefts As New ArrayList
        Static oColumnWidths As New ArrayList
        Static oColumnTypes As New ArrayList
        Static nHeight As Int16
 
        Dim nWidth, i, nRowsPerPage As Int16
        Dim nTop As Int16 = e.MarginBounds.Top
        Dim nLeft As Int16 = e.MarginBounds.Left
 
        If nPageNo = 1 Then
 
            For Each oColumn As DataGridViewColumn In Grid1.Columns
                nWidth = CType(Math.Floor(oColumn.Width / nTotalWidth * _
                  nTotalWidth * (e.MarginBounds.Width / nTotalWidth)), Int16)
 
                nHeight = e.Graphics.MeasureString(oColumn.HeaderText, _
                  oColumn.InheritedStyle.Font, nWidth).Height + 11
 
                oColumnLefts.Add(nLeft)
                oColumnWidths.Add(nWidth)
                oColumnTypes.Add(oColumn.GetType)
                nLeft += nWidth
            Next
        End If
 
        Do While nRowPos <= Grid1.Rows.Count - 1
            Dim oRow As DataGridViewRow = Grid1.Rows(nRowPos)
 
            If nTop + nHeight >= e.MarginBounds.Height + e.MarginBounds.Top Then
                DrawFooter(e, nRowsPerPage)
 
                NewPage = True
                nPageNo += 1
                e.HasMorePages = True
                Exit Sub
            Else
 
                If NewPage Then
                    ' Draw Header
                    e.Graphics.DrawString(Header, New Font(ÜSchriftart, _
                      FontStyle.Bold), Brushes.Black, e.MarginBounds.Left, _
                      e.MarginBounds.Top - e.Graphics.MeasureString(Header, New _
                      Font(ÜSchriftart, FontStyle.Bold), _
                      e.MarginBounds.Width).Height - 13)
 
                    ' Draw Columns
                    nTop = e.MarginBounds.Top
                    i = 0
                    For Each oColumn As DataGridViewColumn In Grid1.Columns
                        e.Graphics.FillRectangle(New SolidBrush( _
                          Drawing.Color.LightGray), New Rectangle(oColumnLefts( _
                          i), nTop, oColumnWidths(i), nHeight))
                        e.Graphics.DrawRectangle(Pens.Black, New Rectangle( _
                        oColumnLefts(i), nTop, oColumnWidths(i), nHeight))
                        e.Graphics.DrawString(oColumn.HeaderText, _
                        oColumn.InheritedStyle.Font, New SolidBrush( _
                        oColumn.InheritedStyle.ForeColor), New RectangleF( _
                        oColumnLefts(i), nTop, oColumnWidths(i), nHeight), _
                        oStringFormat)
                        i += 1
                    Next
                    NewPage = False
                End If
 
                nTop += nHeight
                i = 0
                For Each oCell As DataGridViewCell In oRow.Cells
                    If oColumnTypes(i) Is GetType(DataGridViewTextBoxColumn) _
                      OrElse oColumnTypes(i) Is GetType(DataGridViewLinkColumn) _
                      Then
                        e.Graphics.DrawString(oCell.Value.ToString, _
                        oCell.InheritedStyle.Font, New SolidBrush( _
                        oCell.InheritedStyle.ForeColor), New RectangleF( _
                        oColumnLefts(i), nTop, oColumnWidths(i), nHeight), _
                        oStringFormat)
 
                    ElseIf oColumnTypes(i) Is GetType(DataGridViewButtonColumn) _
                      Then
                        oButton.Text = oCell.Value.ToString
                        oButton.Size = New Size(oColumnWidths(i), nHeight)
                        Dim oBitmap As New Bitmap(oButton.Width, oButton.Height)
                        oButton.DrawToBitmap(oBitmap, New Rectangle(0, 0, _
                          oBitmap.Width, oBitmap.Height))
                        e.Graphics.DrawImage(oBitmap, New Point(oColumnLefts( _
                        i), nTop))

   ElseIf oColumnTypes(i) Is GetType(DataGridViewCheckBoxColumn) Then
                        oCheckbox.Size = New Size(14, 14)
                        oCheckbox.Checked = CType(oCell.Value, Boolean)
                        Dim oBitmap As New Bitmap(oColumnWidths(i), nHeight)
                        Dim oTempGraphics As Graphics = Graphics.FromImage( _
                          oBitmap)
                        oTempGraphics.FillRectangle(Brushes.White, New _
                        Rectangle(0, 0, oBitmap.Width, oBitmap.Height))
                        oCheckbox.DrawToBitmap(oBitmap, New Rectangle(CType(( _
                        oBitmap.Width - oCheckbox.Width) / 2, Int32), CType(( _
                        oBitmap.Height - oCheckbox.Height) / 2, Int32), _
                        oCheckbox.Width, oCheckbox.Height))
                        e.Graphics.DrawImage(oBitmap, New Point(oColumnLefts( _
                        i), nTop))
 
                    ElseIf oColumnTypes(i) Is GetType( _
                      DataGridViewComboBoxColumn) Then
                        oComboBox.Size = New Size(oColumnWidths(i), nHeight)
                        Dim oBitmap As New Bitmap(oComboBox.Width, _
                          oComboBox.Height)
                        oComboBox.DrawToBitmap(oBitmap, New Rectangle(0, 0, _
                        oBitmap.Width, oBitmap.Height))
                        e.Graphics.DrawImage(oBitmap, New Point(oColumnLefts( _
                        i), nTop))
                        e.Graphics.DrawString(oCell.Value.ToString, _
                        oCell.InheritedStyle.Font, New SolidBrush( _
                        oCell.InheritedStyle.ForeColor), New RectangleF( _
                        oColumnLefts(i) + 1, nTop, oColumnWidths(i) - 16, _
                        nHeight), oStringFormatComboBox)
 
                    ElseIf oColumnTypes(i) Is GetType(DataGridViewImageColumn) _
                      Then
                        Dim oCellSize As Rectangle = New Rectangle(oColumnLefts( _
                        i), nTop, oColumnWidths(i), nHeight)
                        Dim oImageSize As Size = CType(oCell.Value, Image).Size
                        e.Graphics.DrawImage(oCell.Value, New Rectangle( _
                          oColumnLefts(i) + CType(((oCellSize.Width - _
                          oImageSize.Width) / 2), Int32), nTop + CType((( _
                          oCellSize.Height - oImageSize.Height) / 2), Int32), _
                          CType(oCell.Value, Image).Width, CType(oCell.Value, _
                          Image).Height))
                    End If
 
                    e.Graphics.DrawRectangle(Pens.Black, New Rectangle( _
                      oColumnLefts(i), nTop, oColumnWidths(i), nHeight))
 
                    i += 1
                Next
            End If
 
            nRowPos += 1
            nRowsPerPage += 1
        Loop
 
        DrawFooter(e, nRowsPerPage)
        e.HasMorePages = False
    End Sub
 
 
    Private Sub DrawFooter(ByVal e As _
      System.Drawing.Printing.PrintPageEventArgs, ByVal RowsPerPage As Int32)
        Dim sPageNo As String = "Seite " & nPageNo.ToString
 
        'Seiteneinstellung checken
        If e.PageSettings.Margins.Top < 10 Then e.PageSettings.Margins.Top = 10
        If e.PageSettings.Margins.Bottom < 10 Then _
          e.PageSettings.Margins.Bottom = 10
 
        'Abstand unten holen
        Dim unten As Integer = e.PageSettings.Margins.Bottom - 15
 
 
        ' Right Align - User Name
        e.Graphics.DrawString(sUserName, ESchriftart, Brushes.Black, _
          e.MarginBounds.Left + (e.MarginBounds.Width - _
          e.Graphics.MeasureString(sPageNo, ESchriftart, _
          e.MarginBounds.Width).Width - 135), e.MarginBounds.Top + _
          e.MarginBounds.Height - unten)
 
        ' Left Align - Date/Time
        e.Graphics.DrawString(Now.ToLongDateString + " " + _
          Now.ToShortTimeString, ESchriftart, Brushes.Black, _
          e.MarginBounds.Left, e.MarginBounds.Top + e.MarginBounds.Height - _
          unten)
 
        ' Center  - Page No. Info
        e.Graphics.DrawString(sPageNo, ESchriftart, Brushes.Black, _
          e.MarginBounds.Left + (e.MarginBounds.Width - _
          e.Graphics.MeasureString(sPageNo, ESchriftart, _
          e.MarginBounds.Width).Width) / 2, e.MarginBounds.Top + _
          e.MarginBounds.Height - unten)
    End Sub

mfg
rt