Zitat:

Was mich optisch stört ist die Tatsache, dass die Buttons nicht sichtbar sind so lange der Text lädt. Kann ich da irgendwie die Priorisierung im Aufbau ändern, so dass erst die äußere Form mit den Buttons und dann der Text geladen wird

Public Class frmEditList
 
    Dim WithEvents btnUndo As New Button With _
        {.Parent = Me, .Text = "UNDO", .Width = 100}
 
    Dim WithEvents btnRedo As New Button With _
        {.Parent = Me, .Text = "REDO", .Width = 100, .Left = 105}
 
    Dim rtb As New RichTextBox With _
        {.Parent = Me, .Top = 40, .Width = 400, .Height = 400, _
         .ScrollBars = RichTextBoxScrollBars.Both}
 
 
    Private Sub frmEditList_Load(sender As System.Object, _
                         e As System.EventArgs) Handles MyBase.Load
 
        Me.FormBorderStyle = _
           Windows.Forms.FormBorderStyle.Fixed3D
 
        Me.Size = New Size(410, 470)
    End Sub
 
 
    Public Property ListToEdit() As List(Of String)
        Set(value As List(Of String))
            Me.Refresh()
            rtb.Clear()
            rtb.Lines = value.ToArray
        End Set
        Get
            Return New List(Of String)(rtb.Lines)
        End Get
    End Property
 
 
    Private Sub btnRedo_Click(sender As Object, _
        e As System.EventArgs) Handles btnRedo.Click
        rtb.Redo()
    End Sub
 
    Private Sub btnUndo_Click(sender As Object, _
        e As System.EventArgs) Handles btnUndo.Click
        rtb.Undo()
    End Sub
End Class

 Public Class frmEditListDemo
 
    Dim texte As New List(Of String)
 
    Dim WithEvents btnEdit As New Button With _
        {.Parent = Me, .Text = "Edit"}
 
    Dim lboText As New ListBox With _
        {.Parent = Me, .Width = 400, .Height = 400, .Top = 40}
 
 
    Private Sub frmEditListDemo_Load(sender As System.Object, _
        e As System.EventArgs) Handles MyBase.Load
 
        Me.Size = New Size(410, 470)
        Me.DoubleBuffered = True 'eventuell
 
        'Demodaten
        For i As Integer = 0 To 1000
            texte.Add("Abschnitt " & (i + 1).ToString)
            texte.Add("Eine Textzeile ohne Informationsgehalt")
            texte.Add _
             ("Noch eine Zeile, die keine nützlichen Angaben enthält")
        Next i
 
        'Datenbindung erstellen
        lboText.DataSource = texte
    End Sub
 
 
    Private Sub btnEdit_Click(sender As Object, _
        e As System.EventArgs) Handles btnEdit.Click
 
        Me.Text = "Edit wird geöffnet ..."
        Me.Enabled = False
        Me.Refresh()
 
        'Edit-Dialog
        Using edit As New frmEditList
            'Liste an Edit-Form übergeben
            edit.ListToEdit = texte
 
            edit.ShowDialog()
 
            Me.Text = "Edit wird geschlossen ..."
            Me.Refresh()
 
            'Liste abfragen
            texte = edit.ListToEdit
        End Using
 
        'Datenbindung erneuern
        With lboText
            .SuspendLayout() 'eventuell
            .DataSource = texte
            .ResumeLayout()
        End With
 
        Me.Text = Me.Name
        Me.Enabled = True
    End Sub
End Class