Public Function gpslink(datei As String) As String
    Dim strFile As String
    Dim strHttp As String
    Dim DestUrl As URL
    'Dim datei As String
 
     'datei = "D:\eigene dateien\vb\datenlogger - totorovic\nmea.txt"
     strdatei = Mid(datei, InStrRev(datei, "\", -1) + 1)
 
    strUrl = "https://www.gpsvisualizer.com/map?output_home"
    strName = "uploaded_file_1"
    strMIMEType = "multipart/form-data"
 
    ' if a request is allredy being sent
    ' exit
    If blnConnected Then Exit Function
 
    ' check that a file was selected
    If datei = vbNullString Then
        MsgBox "No File Chosen", vbCritical, "ERROR"
 
        Exit Function
    End If
 
    ' extract the URL using a helper function
    DestUrl = ExtractUrl(strUrl)
 
    If DestUrl.Host = vbNullString Then
        MsgBox "Invalid Host", vbCritical, "ERROR"
 
        Exit Function
    End If
 
    ' clear the old response
    strResponse = ""
 
    ' read the file contents as a string
    ' N.B: in HTTP everything is a string, even binary files
    strFile = GetFileContents(datei)
 
    ' build the HTTP request
    strHttp = BuildFileUploadRequest(strFile, DestUrl, strName, strdatei, _
      strMIMEType)
 
    ' assign the protocol host and port
    Winsock1.Protocol = sckTCPProtocol
    Winsock1.RemoteHost = DestUrl.Host
 
    If DestUrl.Port <> 0 Then
        Winsock1.RemotePort = DestUrl.Port
    Else
        Winsock1.RemotePort = 80
    End If
 
    ' make the connection and send the HTTP request
    Winsock1.Connect
 
    While Not blnConnected
        DoEvents
    Wend
 
    strRequest = strHttp
    Winsock1.SendData strHttp
 
    While blnConnected
        DoEvents
    Wend
    'Clipboard.SetText strResponse
    'Debug.Print Len(strResponse)
    Dim intview As Integer
    Dim pfad As String
 
    intview = InStr(1, strResponse, "view")
    If intview > 0 Then
        pfad = Mid(strResponse, 1, intview - 3)
        gpslink = Mid(pfad, InStrRev(pfad, "/", -1))
        gpslink = "https://www.gpsvisualizer.com/display" & gpslink & " "
    Else
        gpslink = ""
    End If
 
    If blnConnected Then blnConnected = False
 
End Function

Private Function BuildFileUploadRequest(ByRef strData As String, _
                                        ByRef DestUrl As URL, _
                                        ByVal UploadName As String, _
                                        ByVal FileName As String, _
                                        ByVal MimeType As String) As String
 
    Dim strHttp As String ' holds the entire HTTP request
    Dim strBoundary As String 'the boundary between each entity
    Dim strBody As String ' holds the body of the HTTP request
    Dim lngLength As Long ' the length of the HTTP request
 
    ' create a boundary consisting of a random string
    strBoundary = RandomAlphaNumString(32)
 
    ' create the body of the http request in the form
    '
    ' --boundary
    ' Content-Disposition: form-data; name="UploadName"; filename="FileName"
    ' Content-Type: MimeType
    '
    ' file data here
    '--boundary--
    strBody = "--" & strBoundary & vbCrLf
    strBody = strBody & "Content-Disposition: form-data; name=""" & UploadName _
      & """; filename=""" & _
                    FileName & """" & vbCrLf
    strBody = strBody & "Content-Type: " & MimeType & vbCrLf
    strBody = strBody & vbCrLf & strData
    strBody = strBody & vbCrLf & "--" & strBoundary & "--"
 
    ' find the length of the request body - this is required for the
    ' Content-Length header
    lngLength = Len(strBody)
 
    ' construct the HTTP request in the form:
    '
    ' POST /path/to/reosurce HTTP/1.0
    ' Host: host
    ' Content-Type: multipart-form-data, boundary=boundary
    ' Content-Length: len(strbody)
    '
    ' HTTP request body
    strHttp = "POST " & DestUrl.URI & "?" & DestUrl.Query & " HTTP/1.0" & vbCrLf
    strHttp = strHttp & "Host: " & DestUrl.Host & vbCrLf
    strHttp = strHttp & "Content-Type: multipart/form-data, boundary=" & _
      strBoundary & vbCrLf
    strHttp = strHttp & "Content-Length: " & lngLength & vbCrLf & vbCrLf
    strHttp = strHttp & strBody
 
    BuildFileUploadRequest = strHttp
End Function