Public Class frmRTF
 
    'Klasse für Text-Abschnitt und RTF-Parameter
    'mit Standardwerten
    Private Class RTFParams
        Public text As String = ""
        Public Forecolor As Drawing.Color = Color.Black
        Public Backcolor As Drawing.Color = Color.White
        Public font As Drawing.Font = _
           New Font("Arial", 12, Drawing.FontStyle.Regular)
        Public indent As Integer = 0
    End Class
 
 
    Dim rtf As New RichTextBox With _
       {.Parent = Me, .Dock = DockStyle.Fill}
 
 
    Private Sub frmRTF_Load(sender As System.Object, _
         e As System.EventArgs) Handles MyBase.Load
 
       'Liste für Textabschnitte
       Dim rtfparts As New List(Of RTFParams)
 
       'Ein Beispieltext
       With rtfparts
          .Add(New RTFParams With {.text = "Das ist ein schöner Text!" & _
                 vbCrLf & vbCrLf, .indent = 12})
 
          .Add(New RTFParams With _
                 {.text = "Das ist ein noch", .Forecolor = Color.Red, _
                .font = New Font("Arial", 12, FontStyle.Bold)})
          .Add(New RTFParams With _
              {.text = " sehr viel", .Forecolor = Color.Blue})
          .Add(New RTFParams With {.text = " schönerer Text!"})
        End With
 
        'Textabschnitte im Control zusammenfügen
        CreateRTFText(rtfparts)
    End Sub
 
 
    Private Sub CreateRTFText(ByVal rtfparts As List(Of RTFParams))
 
        For i As Integer = 0 To rtfparts.Count - 1
            With rtfparts(i)
                If Not String.IsNullOrWhiteSpace(.text) Then
                    rtf.SelectionColor = .Forecolor
                    rtf.SelectionBackColor = .Backcolor
                    rtf.SelectionFont = .font
                    rtf.SelectionIndent = .indent
                    rtf.AppendText(.text)
                End If
            End With
        Next i
    End Sub
End Class

Salzburger

Salzburger