vb@rchiv · Tipps & Tricks · DNS-Suchreihenfolge konfigurieren (WMI)

Rubrik: HTML/Internet/Netzwerk · Netzwerk | VB-Versionen: VB4, VB5, VB6

22.06.04

DNS-Suchreihenfolge konfigurieren (WMI) Hier ein bisschen WMI, um die DNS-Konfig vorzunehmen.
Autor: Gerhard Kuklau	Bewertung:	Views: 15.246
ohne Homepage	System: WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Diesmal möchten wir Ihnen zeigen, wie man mit Hilfe des WMI-Objekts die DNS-Suchreihenfolge konfiguiert.

' Konfigurieren der (Such-) Reihenfolge der DNS-Server
Public Function fConfig_DNS_SearchOrder( _
  PrimaryDNS As String, _
  SecondaryDNS As String, _
  Optional ComputerName As String = ".") As Boolean
 
  Dim oWMI As Object
  Dim oNIC As Variant
  Dim colNIC As Variant
  Dim DNSServers As Variant
 
  ' Fehlerbehandlung aktivieren
  On Error GoTo ErrHandler
 
  ' WMI-Objekt erstellen
  Set oWMI = GetObject("winmgmts:\\" & ComputerName & "\root\cimv2")
 
  ' WMI-Abfrage erstellen
  Set colNIC = oWMI.ExecQuery _
    ("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
 
  ' DNS-Suchreihenfolge festlegen
  For Each oNIC In colNIC
    DNSServers = Array(PrimaryDNS, SecondaryDNS)
    oNIC.SetDNSServerSearchOrder (DNSServers)
  Next   
  fConfig_DNS_SearchOrder = True
  Exit Function
 
ErrHandler:
  fConfig_DNS_SearchOrder = False
End Function

Beispiel für den Aufruf:

Dim bResult As Boolean
Dim sPrimary As String
Dim sSecondary As String
 
' bevorzugter DNS-Server
sPrimary = "192.168.120.252"
 
' alternativer DNS-Server
sSecondary = "192.168.120.253"
 
' DNS-Suchreihenfolge festlegen
bResult = fConfig_DNS_SearchOrder(sPrimary, sSecondary)

Hinweis:
Wenn man die entsprechenden Rechte hat, dann braucht man für Computername anstelle des "." nur den gewünschten Rechnernamen eintragen und schon kann man die Konfiguration remote aus der Ferne (also von einem anderen Rechner aus) vornehmen.