Alle Child-Formen einer MDI-Anwendung ermitteln/schließen Zum korrekten Beenden einer MDI-Anwendung sollten zunächst alle Child-Formen geschlossen werden. Dieser Tipp zeigt, wie sich das realisieren lässt.
Autor:   Dieter Otter	Bewertung:	Views:  19.564
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Innerhalb einer MDI-Anwendung können bekanntlich mehrere Child-Formen gleichzeitig geöffnet sein. Die Anzahl der aktuell geladenen "Kind-Fenster" lässt sich wie folgt ermitteln:

' Anzahl der aktuell geladenenen ChildFormen ermitteln
Public Function CountChildForms() As Long
  Dim oForm As Form
 
  ' alle Formen durchlauden
  For Each oForm In VB.Forms
    ' Handelt es sich um eine "normale" Form?
    If Not TypeOf oForm Is MDIForm Then
      ' Handelt es sich um eine ChildForm?
      If oForm.MDIChild = True Then
        CountChildForms = CountChildForms + 1
      End If
    End If
  Next
End Function

Diese Funktion ist bspw. immer dann nützlich, wenn man per "Knopfdruck" alle geöffneten Kindfenster schließen möchte. Der Menübefehl hierzu sollte in diesem Fall aber nur dann "aktiv" sein, wenn auch mindestens ein Kindfenster geladen ist:

mnuCloseAll.Enabled = (CountChildForms() > 0)

Sollen jetzt alle Kindfenster geschlossen werden, gehen Sie wie folgt vor:

' Alle ChildFormen schließen
Public Function CloseAllChildForms() As Boolean
  Dim oForm As Form
 
  ' alle Formen durchlaufen
  For Each oForm In VB.Forms
    ' Handelt es sich um eine "normale" Form?
    If Not TypeOf oForm Is MDIForm Then
      ' Handelt es sich um eine ChildForm?
      If oForm.MDIChild = True Then
        ' Form entladen
        Unload oForm
      End If
    End If
  Next
 
  ' True zurückgeben, wenn tatsächlich alle ChildFormen
  ' geschlossen wurden
  CloseAllChildForms = (CountChildForms() = 0)
End Function

Der Rückgabewert der Funktion ist immer dann interessant, wenn bspw. die MDI-Anwendung beendet werden soll:

' Anwendung beenden
Private Sub mnuExit_Click()
  ' zunächst alle Kindfenster schließen
  If CloseAllChildForms() Then
    ' Anwendung nur beenden, wenn alle Fenster geschlossen werden konnten
    Unload Me
  End If
End Sub

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.