vb@rchiv · Tipps & Tricks · Aufklappbreite der ComboBox festlegen

Rubrik: Controls · ComboBox | VB-Versionen: VB4, VB5, VB6

13.12.04

Aufklappbreite der ComboBox festlegen Hier zeigen wir, wie sich die Breite der aufgeklappten ComboBox-Liste individuell anpassen lässt.
Autor: Dieter Otter	Bewertung:	Views: 18.546
www.tools4vb.de	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Kennen Sie das? Sie verwenden eine ComboBox und beim Aufklappen werden längere Listeneinträge nicht vollständig angezeigt. Grund ist, dass die Liste standardmäßig immer in der Breite der ComboBox angezeigt wird.

Mit Hilfe des Windows-API lässt sich die Aufklappbreite der Liste jedoch individuell ändern.

Fügen Sie hierzu nachfolgenden Code in ein Modul ein:

Option Explicit
 
' benötigte API-Deklarationen
Public Declare Function SendMessage Lib "User32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Long) As Long
 
Private Const CB_SETDROPPEDWIDTH = &H160

Die Breite der ComboBox-Liste lässt sich jetzt wie folgt ändern:

' ListBox-Breite auf 2000 Twips festlegen
SendMessage Combo1.hwnd, CB_SETDROPPEDWIDTH, (2000 / Screen.TwipsPerPixelX), 0&

Das funktioniert jetzt schon ganz gut. Allerdings muss man die Breite jetzt immer "fix" angeben. Besser wäre es, wenn man zusätzlich die Möglichkeit hätte, die Breite der ListBox autom. an den längsten Eintrag anzupassen.

Hierzu "basteln" wir uns einfach eine universelle Funktion, die ebenfalls im Modul "abgelegt" wird.

' Aufklappbreite der ComboBox-Liste fix oder
' autom. anhand des längsten Eintrag festlegen
Public Sub ComboSetListWidth(oCombo As Object, _
  Optional ByVal nFixWidth As Variant, _
  Optional ByVal nScaleMode As Variant)
 
  With oCombo
    ' Falls keine Maßeinheit angegeben,
    ' autom. die ScaleMode-Eigenschaft der Form
    ' verwenden
    If IsMissing(nScaleMode) Or IsMissing(nFixWidth) Then 
      nScaleMode = .Parent.ScaleMode
    End If
 
    ' Falls Parameter "nFixWidth" nicht angegeben,
    ' längsten Eintrag ermitteln
    If IsMissing(nFixWidth) Then
      Dim i As Long
      Dim nWidth As Long
 
      nFixWidth = 0
      For i = 0 To .ListCount - 1
        nWidth = .Parent.TextWidth(.List(i))
        If nWidth > nFixWidth Then nFixWidth = nWidth
      Next i
 
      ' Plus kleine Zugabe
      nFixWidth = nFixWidth + .Parent.ScaleX(10, vbPixels, nScaleMode)
 
      ' Falls mehr als 8 Einträge, nochmals kleine Zugabe wegen der Scrollbar
      If .ListCount > 8 Then
        nFixWidth = nFixWidth + .Parent.ScaleX(15, vbPixels, nScaleMode)
      End If
    End If
 
    ' Neue Aufklappbreite jetzt zuweisen
    SendMessage .hwnd, CB_SETDROPPEDWIDTH, _
      .Parent.ScaleX(nFixWidth, nScaleMode, vbPixels), 0&
  End With
End Sub

Aufrufbeispiele:

' Breite der ListBox autom. anpassen
ComboSetListWidth Combo1

' Breite der ListBox fest auf 2000 Twips festlegen
ComboSetListWidth Combo1, 2000, vbTwips

' Breite der ListBox fest auf 250 Pixel festlegen
ComboSetListWidth Combo1, 250, vbPixels