vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Controls · Sonstiges   |   VB-Versionen: VB4, VB5, VB621.02.05
autom. Navigation im SSTab-Control

Dieser Tipp zeigt wie sich beim Drücken der TAB-Taste im letzten Eingabecontrol einer Registerkarte autom. die nächste Registerkarte im SSTab-Control öffnen lässt.

Autor:   Wolfgang ChristBewertung:  Views:  14.629 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Wäre das nicht toll, wenn beim Drücken der TAB-Taste im letzten Eingabecontrol einer Registerkarte autom. die nächste Registerkarte im SSTab-Control geöffnet werden würde?
Auf diese Weise müsste der Anwender also nicht extra zur Maus greifen und die nächste Registerlasche anklicken.

Ok... kurze Überlegung... alles klar
Wenn das letzte Control verlassen wurde (LostFocus), müssen wir einfach prüfen, ob dies mittels der TAB-Taste passiert ist. Wenn ja, dann nächste Registerkarte aktivieren und nochmals die TAB-Taste senden, um autom. das erste Control der neuen Registerkarte zu aktivieren.

Fügen Sie hierzu nachfolgenden Code in den Codeteil der Form ein:

Option Explicit
 
' API - Funktionen
Private Declare Function GetKeyboardState Lib "user32" ( _
  pbKeyState As Byte) As Long
 
' benötigte Konstanten
Private Const VK_TAB = &H9
Private Const VK_SHIFT = &H10
' Prüft, ob Tab-Taste gedrückt wurde.
' Optional in Verbindung mit der Shift-Taste
Public Function CheckIfTabPressed( _
  Optional ByVal bWithShift As Boolean = False) As Boolean
 
  Dim bKeyArray(255) As Byte
 
  ' Status ermitteln
  Call GetKeyboardState(bKeyArray(0))
 
  ' 1. Prüfung: wurde TAB gedrückt ?
  If ((bKeyArray(VK_TAB) And &H80) = &H80) Then
    ' 2. Prüfung: SHIFT od. NICHT SHIFT
    If bWithShift Then
      ' Ist Shift gedrückt ?
      CheckIfTabPressed = ((bKeyArray(VK_SHIFT) And &H80) = &H80)
    Else
      ' Ist Shift nicht gedrückt ?
      CheckIfTabPressed = ((bKeyArray(VK_SHIFT) And &H80) <> &H80)
    End If
  Else
    ' Tab wurde nicht gedrückt
    CheckIfTabPressed = False
  End If
End Function

Wie wendet man die Funktion nun an?
Fügen Sie dem Formular ein SSTab-Control hinzu. Platzieren Sie auf die 1. Registerkarte 2 TextBox-Controls (Text1 und Text2) und auf die 2. Registerkarte ebenfalls ein paar TextBox-Controls (Text3, Text4 und Text5). Auf die 3. Registerkarte platzieren Sie nur ein Control (Text6). Damit der Code korrekt funktioniert muss peinlichst auf die korrekte TAB-Reihenfolge geachtet werden, d.h. das SSTab-Control bekommt den TabIndex=0, die 1. TextBox den TabIndex=1, die 2. TextBox den TabIndex=3 usw.

Private Sub Form_Load()
  ' 1. Registerkarte aktivieren
  SSTab1.Tab = 0
 
  ' 1. Control aktivieren
  SendKeys "{TAB}"
End Sub
Private Sub Text1_LostFocus()
  If CheckIfTabPressed(True) Then
    ' Bei Shift+TAB letzte Registerkarte aktivieren
    SSTab1.Tab = SSTab1.Tabs - 1
    SendKeys "{TAB}", True
  End If
End Sub
Private Sub Text2_LostFocus()
  If CheckIfTabPressed(False) Then
    ' Bei TAB nächste Registerkarte aktivieren
    SSTab1.Tab = SSTab1.Tab + 1
    SendKeys "{TAB}", True
  End If
End Sub
Private Sub Text3_LostFocus()
  If CheckIfTabPressed(True) Then
    ' Bei Shift+TAB vorige Registerkarte aktivieren
    SSTab1.Tab = SSTab1.Tab - 1
    SendKeys "{TAB}", True
  End If
End Sub
Private Sub Text5_LostFocus()
  If CheckIfTabPressed(False) Then
    ' Bei TAB nächste Registerkarte aktivieren
    SSTab1.Tab = SSTab1.Tab + 1
    SendKeys "{TAB}", True
  End If
End Sub
Private Sub Text6_LostFocus()
  If CheckIfTabPressed(True) Then
    ' Bei Shift+TAB vorige Registerkarte aktivieren
    SSTab1.Tab = SSTab1.Tab - 1
    SendKeys "{TAB}", True
  ElseIf CheckIfTabPressed(False) Then
    ' bei TAB 1. Registerkarte aktivieren
    SSTab1.Tab = 0
    SendKeys "{TAB}", True
  End If
End Sub



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2019 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.