Vorsicht mit dem Variant-Datentyp! Ist eine Objekt-Variable als Variant deklariert gilt absolute Vorsicht!
Autor:   Dieter Otter	Bewertung:	Views:  12.752
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Folgendes Szenario: Sie haben eine Prozedur, in deren Prozedurdeklaration der erwartete Parameter vom Typ Variant deklariert ist. Der Prozedur soll hier entweder ein Control oder der Name des Controls als String übergeben werden - deshalb der Datentyp Variant.

Private Sub SetColor(oControl As Variant, ByVal nColor As Long, _
  Optional ByVal bBold As Boolean = False)

Über die VarType-Funktion von VB fragen Sie nun als erstes ab, ob der übergebene Parameter "oControl" vom Typ "String" ist:

If VarType(oControl) = vbString Then

Falls es sich um einen String handelt, erfolgen die Wertzuweisungen wie folgt:

With Me.Controls(oControl)
  .ForeColor = nColor
  .FontBold = bBold
End With

andernfalls so:

With oControl
  .ForeColor = nColor
  .FontBold = bBold
End With

Der gesamte Prozedurcode sieht dann so aus:

Private Sub SetColor(oControl As Variant, ByVal nColor As Long, _
  Optional ByVal bBold As Boolean = False)
 
  If VarType(oControl) = vbString Then
    With Me.Controls(oControl)
      .ForeColor = nColor
      .FontBold = bBold
    End With
  Else
    With oControl
      .ForeColor = nColor
      .FontBold = bBold
    End With
  End If
End Sub

Das Ganze funktioniert soweit auch, doch urplötzlich kommt es in der Prozedur zum Laufzeitfehler 13 - Typen unverträglich! - und zwar dann, wenn für den Parameter "oControl" das Control selbst und nicht dessen Name übergeben wurde.

Beispiel:
Fügen Sie obige Prozedur in den Codeteil der Form ein. Platzieren Sie auf die Form ein paar TextBox-Controls. Dazu noch einen CommandButton mit folgendem Code:

Private Sub Command1_Click()
  SetColor "Text1", vbRed
  SetColor Text2, vbRed
End Sub

Starten Sie das Projekt und siehe da: Fehler 13!

Der Code hält an dieser Stelle an - und zwar dann, wenn als Parameter die 2. TextBox als Control übergeben wurde:

If VarType(oControl) = vbString Then
    With Me.Controls(oControl)

Jetzt werden Sie sich sicher fragen: Warum durchläuft die Prozedur den oberen Teil und nicht den zweiten Teil der Abfrage? Schließlich haben Sie das Control ja direkt als solches an die Prozedur übergeben und nicht als String! Und genau hier liegt das Problem! Die meisten Controls verfügen über eine Standard-Eigenschaft, die VB verwendet, wenn man keine Eigenschaft explizit angibt. Die Standard-Eigenschaft der TextBox ist wie allseits bekannt: Text. D.h.: Wenn Sie der Prozedur Text2 als Parameter übergeben, interpretiert die Prozedur den Parameter als STRING, da VB "denkt", Sie wollten die Text-Eigenschaft verwenden (da Standard-Eigenschaft)!

Auf deutsch: VB interpretiert den Aufruf:

SetColor Text2, vbRed

als:

SetColor Text2.Text, vbRed

Wie kann man die Prozedur aber dennoch universell verwenden, so dass entweder das Control selbst oder der Controlname übergeben werden kann?

Die Lösung lautet: IsObject!

Wir dürfen in der Prozedur also nicht die VarType-Funktion verwenden, sondern müssen den Parameter explizit auf "Objekt" prüfen:

Private Sub SetColor(oControl As Variant, ByVal nColor As Long, _
  Optional ByVal bBold As Boolean = False)
 
  If Not IsObject(oControl) Then
    With Me.Controls(oControl)
      .ForeColor = nColor
      .FontBold = bBold
    End With
  Else
    With oControl
      .ForeColor = nColor
      .FontBold = bBold
    End With
  End If
End Sub

Dann klappt's auch mit VB
 

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.