vb@rchiv · Tipps & Tricks · Flackern der RichtTextBox unterbinden

Rubrik: Controls · TextBox & RichTextBox | VB-Versionen: VB4, VB5, VB6

28.04.06

Flackern der RichtTextBox unterbinden Durch Abschalten des autom. Neuzeichnens lässt sich das Flackern bei großen Änderungen in der RichTextBox unterbinden.
Autor: Dieter Otter	Bewertung:	Views: 12.283
www.tools4vb.de	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Nehmen wir an, Sie verwenden eine RichTextBox, in der nachträglich viele Textpassagen formatiert werden sollen (zB. Einfärbungen). Je umfangreicher die Änderungen sind, desto störender wirkt sich das ständige Aktualisieren des Inhaltes der RichTextBox aus.

Wie man dieses "Flackern" abschalten kann, möchten wir Ihnen heute zeigen.

Variante 1:
Während der Text-Formatierung schalten Sie die RichTextBox einfach aus und danach wieder an:

With RichTextBox1
  .Visible = False
 
  ' hier der Code für die Änderungen am Text-Inhalt
  ...
 
  .Visible = True
End With

Variante 2:
Diese Variante ist etwas umfangreicher und schaltet das autom. Neuzeichnen des Controls via API-Funktion aus - dafür bleibt das Control aber sichtbar.

Option Explicit
 
' benötigte API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Long) As Long
 
Private Declare Function GetClientRect Lib "user32" ( _
  ByVal hWnd As Long, _
  lpRect As cRECT) As Long
 
Private Declare Function RedrawWindow Lib "user32" ( _
  ByVal hWnd As Long, _
  lprcUpdate As cRECT, _
  ByVal hrgnUpdate As Long, _
  ByVal fuRedraw As Long) As Long
 
Private Const WM_SETREDRAW = &HB
Private Const RDW_INVALIDATE = &H1
Private Const RDW_ALLCHILDREN = &H80
Private Const RDW_UPDATENOW = &H100
Private Const RDW_ERASE = &H4
 
Private Type cRECT
  left As Long
  top As Long
  right As Long
  bottom As Long
End Type

Public Sub LockWindow(ByVal hWnd As Long, ByVal bLock As Boolean)
  Dim ClientRect As cRECT
 
  If bLock = True Then
    ' Neuzeichnen ausschalten
    SendMessage hWnd, WM_SETREDRAW, False, 0&
  Else
    ' Neuzeichnen einschalten
    SendMessage hWnd, WM_SETREDRAW, True, 0&
 
    ' Größe des Windows (Controls) ermitteln
    GetClientRect hWnd, ClientRect
 
    ' Inhalt aktualisieren
    RedrawWindow hWnd, ClientRect, 0&, RDW_ERASE Or _
      RDW_INVALIDATE Or RDW_ALLCHILDREN Or RDW_UPDATENOW
  End If
End Sub

Aufrufbeispiel:

With RichTextBox1
  LockWindow .hWnd, True
 
  ' hier der Code für die Änderungen am Text-Inhalt
  ...
 
  .LockWindow .hWnd, False
End With