vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Variablen/Strings · Algorithmen/Mathematik   |   VB-Versionen: VB5, VB602.08.06
Prüfen von internationalen Kontonummern (IBAN-Check)

Mit diesem Code lassen sich Kontonummern in internationaler Syntax (IBAN) prüfen.

Autor:   Gunnar F. BartelBewertung:  Views:  25.503 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Mit diesem Code lassen sich Kontonummern in internationaler Syntax (IBAN) prüfen. Fügen Sie hierzu nachfolgenden Code in ein Modul ein:

Public Function IBANOK(ByVal IBAN As String) As Boolean
  Dim IBANstr As String
  Dim i As Long
 
  IBANstr = Replace(IBAN, " ", "")
 
  ' erste 4 Stellen Länderocde & Prüfziffer und dann 
  ' KontoIdent ... niemals kürzer als 5!
  If Len(IBANstr) < 5 Then 
    IBANOK = False
    Exit Function
  End If
 
  IBANstr = Mid(IBANstr, 5) & Mid(IBANstr, 1, 4)
 
  For i = 65 To 90
    IBANstr = Replace(IBANstr, Chr(i), i - 64 + 9, , , vbTextCompare)
  Next
 
  IBANOK = ModuloBig(IBANstr, 97) = 1
 
  ' Verfahrenserklärung
  ' 
  ' Quelle: http://de.wikipedia.org/wiki/International_Bank_Account_Number#Validierung_der_Pr.C3.BCfsumme
  ' 
  ' Wie bei der Berechnung werden zunächst die ersten vier Stellen ans Ende gestellt,
  ' alle Leerzeichen entfernt und die Buchstaben durch die Zahl,
  ' die ihre Position im Alphabet repräsentiert, + 9 ersetzt.
  ' Nun wird der Rest berechnet, der sich beim Teilen der Zahl durch 97 ergibt (Modulo 97).
  ' Das Ergebnis muss 1 sein, ansonsten ist die IBAN falsch.
  ' 
  ' Beispiel:
  ' 
  ' IBAN:       DE68 2105 0170 0012 3456 78
  ' Umstellung: 2105 0170 0012 3456 78DE 68
  ' Modulus:    210501700012345678131468 mod 97 = 1
End Function
' Funktion für MOD-Operationen für große Zahlen
Function ModuloBig(ZahlString As String, Divisor As Long) As Long
  Dim TeilStart As Long
  Dim TeilEnd As Long
  Dim Erg As Long
  Dim Rest As Long
  Dim ErgebnisGanzString As String
  Dim TeilZahl As Long
 
  TeilStart = 1
  TeilEnd = 1
 
  Do While TeilEnd <= Len(ZahlString)
    TeilZahl = Val(Rest & Mid(ZahlString, TeilStart, TeilEnd - TeilStart + 1))
 
    If TeilZahl >= Divisor Then
      Erg = Int(TeilZahl / Divisor)
      Rest = TeilZahl - Erg * Divisor
 
      ErgebnisGanzString = ErgebnisGanzString + CStr(Erg)
 
      TeilStart = TeilEnd + 1
      TeilEnd = TeilStart
    Else
      If ErgebnisGanzString <> "" Then
        ErgebnisGanzString = ErgebnisGanzString & "0"
      End If
 
      TeilEnd = TeilEnd + 1
    End If
  Loop
 
  If TeilStart <= Len(ZahlString) Then
    Rest = Val(Rest & Mid(ZahlString, TeilStart))
  End If
 
  ' ErgebnisGanzString enthält jetzt das "Ganzzahlige" 
  ' Ergebnis ohne Rest, wird z.Z. aber nicht verwendet
 
  ModuloBig = Rest
End Function

Anwendungsbeispiel:
Platzieren Sie auf die Form eine neue TextBox "txtIBAN" und fügen folgenden Code in den Codeteil der Form:

Private Sub txtIBAN_Validate(Cancel As Boolean)
  If IBANOK(txtIBAN.Text) Then
    ' Konto-Nr. korrekt
    txtIBAN.ForeColor = vbGreen
  Else
    ' Konto-Nr. falsch
    txtIBAN.ForeColor = vbRed
  End If
End Sub



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2019 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.