MP3-Informationen auslesen Auslesen der Tag-Informationen einer MP3-Datei, wie Titel des Songs, Interpret, Erscheinunghsjahr, etc.
Autor:   Dieter Otter	Bewertung:	Views:  22.904
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

MP3-Dateien werden immer beliebter - lassen sich doch so fast 200 Songs auf eine einzige CD brennen. Jede MP3-Datei enthält hierbei Informationen über den Interpret, Erscheinungsjahr, Titel und einiges mehr.

Der nachfolgende Tipp zeigt, wie man mit VB eben diese Informationen auslesen kann.

' Informationen
Public Type MP3Info
  Titel As String
  Interpret As String
  Album As String
  Jahr As String
  Kommentar As String
  Genre As String
End Type 
 
Public Function ReadMP3Tag(ByVal Filename _
  As String) As MP3Info
 
  Dim F As Integer
  Dim TagInfo As String * 128
 
  F = FreeFile
  Open Filename For Binary As #F
  Seek #F, LOF(F) - Len(TagInfo) + 1
  Get #F, , TagInfo
  Close #F
 
  If Left$(TagInfo, 3) <> "TAG" Then
    ' kein TAG
 
  Else
    With ReadMP3Tag
      .Titel = StripNull(Mid$(TagInfo, 4, 30))
      .Interpret = StripNull(Mid$(TagInfo, 34, 30))
      .Album = StripNull(Mid$(TagInfo, 64, 30))
      .Jahr = StripNull(Mid$(TagInfo, 94, 4))
      .Kommentar = StripNull(Mid$(TagInfo, 98, 30))
      .Genre = StripNull(Mid$(TagInfo, 128, 1))
    End With
  End If
End Function
 
Public Function StripNull(ByVal strText As String) _
  As String
 
  If InStr(strText, Chr$(0)) > 0 Then _
    strText = Left$(strText, InStr(strText, Chr$(0)) - 1)
 
  StripNull = RTrim$(strText)
End Function

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.