vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Dateisystem · Dateien - allgemein   |   VB-Versionen: VB2005, VB200806.03.09
Standard-Dateibeschreibung ermitteln

Dieser Tipp verrät, wie sich die Standard-Dateibeschreibung einer Datei ermitteln lässt, so wie sie auch vom Windows Explorer angezeigt wird.

Autor:   Dieter OtterBewertung:  Views:  9.349 
www.tools4vb.deSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Dieser Tipp verrät, wie sich die Standard-Dateibeschreibung einer Datei ermitteln lässt, so wie sie auch vom Windows Explorer angezeigt wird (wie bspw. Adobe Acrobat Dokument, Microsoft Office Access-Anwendung usw.).

Fügen Sie hierzu nachfolgenden Code in Ihr Projekt ein:

Imports System.Runtime.InteropServices
' Benötigte API-Deklarationen
Private Declare Auto Function SHGetFileInfo Lib "shell32.dll" ( _
  ByVal pszPath As String, _
  ByVal dwFileAttributes As Integer, _
  ByRef psfi As SHFILEINFO, _
  ByVal cbFileInfo As Integer, _
  ByVal uFlags As Integer) As IntPtr
 
Private Const SHGFI_TYPENAME = &H400
Private Const MAX_PATH = 260
 
<StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)> _
Private Structure SHFILEINFO
  Public hIcon As IntPtr
  Public iIcon As Integer
  Public dwAttributes As Integer
  <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=MAX_PATH)> _
  Public szDisplayName As String
  <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=80)> _
  Public szTypeName As String
End Structure
''' <summary>
''' Ermittelt die Standard-Dateibeschreibung der übergebenen Datei
''' </summary>
''' <param name="Filename">Dateiname mit vollständiger Pfadangabe</param>
''' <returns>Standard-Dateibeschreibung wie im Windows Explorer angezeigt</returns>
Public Function GetFileDescription(ByVal Filename As String) As String
  ' SHFileInfo-Struktur initialisieren
  Dim oInfo As New SHFILEINFO
 
  ' Aufruf der API-Funktion
  SHGetFileInfo(Filename, 0, oInfo, Marshal.SizeOf(oInfo), SHGFI_TYPENAME)
 
  ' Standard-Dateibeschreibung zurückgeben
  If Not IsNothing(oInfo.szTypeName) Then
    Return oInfo.szTypeName
  Else
    Return ""
  End If
End Function

Aufrufbeispiel:

Label1.Text = GetFileDescription("d:\test.txt")



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.