Tabellenverknüpfungen aktualisieren (ADO) Eine Funktion, mit der sich die Pfade zu verknüpften Tabellen innerhalb einer Access-Datenbank aktualisieren lassen.
Autor:   Dieter Otter	Bewertung:	Views:  17.092
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Vor kurzem haben wir Ihnen gezeigt, wie man per Quellcode Verknüpfungen zu externeb Datenbank-Tabellen in eine bestehende Datenbank einfügen kann.

Jetzt kommt es natürlich auch vor, dass sich der Speicherort (sprich Laufwerk und Verzeichnis) der externen Datenbanken ändert, so dass die Verknüpfungen auf eingebundene Tabellen nicht mehr funktioniert.

Mit nachfolgendem Code lassen sich die Pfadangaben aktualisieren.

' Tabellenverknüpfungen prüfen und ggf. aktualisieren
Public Function dbRefreshLink(ByRef oConn As ADODB.Connection, _
  ByVal sNewPath As String, _
  Optional ByVal sExternTable As String = "") As Boolean
 
  Dim oRs As ADODB.Recordset
  Dim oCat As ADOX.Catalog
  Dim sTable As String
  Dim sPath As String
  Dim sFile As String
 
  ' Fehlerbehandlung aktivieren
  On Error GoTo ErrHandler
 
  ' ggf. abschließenden Backslash anfügen
  If Right$(sNewPath, 1) <> "\" Then sNewPath = sNewPath & "\"
 
  ' Katalog-Objekt der aktiven Connection erstellen
  Set oCat = New ADOX.Catalog
  oCat.ActiveConnection = oConn
 
  ' Datenbank-Schema lesen
  Set oRs = oConn.OpenSchema(adSchemaTables)
  Do Until oRs.EOF
    ' Handelt es sich um eine Tabellenverknüpfung?
    If oRs("TABLE_TYPE") = "LINK" Then
 
      ' Name der Tabelle ermitteln
      sTable = "" & oRs("TABLE_NAME")
 
      ' Handelt es sich um die zu aktualisierende Tabellenverknüpfung?
      If sTable = sExternTable Or Len(sExternTable) = 0 Then
 
        With oCat.Tables(sTable)
          ' Pfad zur externen Datenquelle ermitteln
          sPath = "" & .Properties("Jet OLEDB:Link Datasource")
          If InStr(sPath, "\") > 0 Then
            ' Pfad und Dateiname splitten
            sFile = Mid$(sPath, InStrRev(sPath, "\") + 1)
            sPath = Left$(sPath, InStrRev(sPath, "\"))
 
            ' Pfad aktualisieren, falls notwendig
            If LCase$(sPath) <> LCase$(sNewPath) Then
              .Properties("JET OLEDB:Link Datasource") = sNewPath & sFile
            End If
          End If
        End With
      End If
    End If
    oRs.MoveNext
  Loop
 
  ' Aufräumen - Objekte schließen und freigeben
  oRs.Close
  Set oRs = Nothing
  Set oCat = Nothing
 
  dbRefreshLink = True
  On Error GoTo 0
  Exit Function
 
ErrHandler:
  MsgBox "Tabellenverknüpfung konnte nicht aktualisiert werden!" & vbCrLf & _
    "Fehler " & CStr(Err.Number) & vbCrLf & Err.Description
  dbRefreshLink = False
  Set oCat = Nothing
End Function

Für das Aktualisieren der Tabellenverknüpfungen benötigen wir einen Verweis auf die Microsoft ADO Ext 2.x for DDL and Security Library.

Aufrufbeispiel:
Sicherstellen, dass die verknüpfte Tabelle "KundenExt" auf die korrekte externe Datenquelle verweist.

' Eigene Datenbank öffnen
Dim oConn As ADODB.Connection
Set oConn = New ADODB.Connection
With oConn
  .Provider = "Microsoft.Jet.OLEDB.4.0"
  .Properties("Data Source") = App.Path & "\MyMDB.mdb"
  .Properties("Persist Security Info") = False
  .Open 
End With
 
' jetzt die Tabellenverknüpfung erstellen und hinzufügen
If dbRefreshLink(oConn, "d:\temp", "KundenExt") Then
  ' ...
End If

Tipp:
Wenn Sie den Parameter "sExternTable" weglassen, werden alle in der Quell-Datenbank vorhandenen Tabellenverknüpfungen aktualisiert.

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.