Verwischen eines Bildes (Unscharf machen) Dieses Beispiel zeigt, wie sich die Farben eines Bildes so ändern lässen, so dass das Bild unscharf wird.
Autor:   Sven	Bewertung:	Views:  14.497
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Das nachfolgende Beispiel zeigt, wie sich ein Bild in einer PictureBox "verwischen" lässt. Hierzu werden die Farbwerte zweier nebeneinander liegenden Farben zusammenaddiert und durch 2 geteilt, um so den Mittel-Farbwert zu ermitteln. Dadurch entsteht der "Verwisch"-Effekt. Je häufiger das "Verwischen" auf das Bild angewandt wird, desto unschärfer wird das Bild.

Alles, was Sie für nachfolgenden Tipp brauchen, ist eine Form, eine PictureBox, sowie ein CommandButton. Laden Sie ein beliebiges Bild in die PictureBox. Beim Klicken auf den CommandButton wird der "Verwisch"-Effekt ausgeführt. Beim ersten Mal ist noch kein großer Unterschied zum Original festzustellen. Klicken Sie daher ruhig mehrmals auf den Button.

Und hier der Code

Option Explicit
 
' Bild verwischen
Public Sub Verwischen(Bildfeld As PictureBox)
  Dim X As Long
  Dim Y As Long
  Dim Color1 As Long
  Dim Color2 As Long
  Dim oScaleMode As Integer
  Dim oAutoRedraw As Boolean
 
  With Bildfeld
    ' alten ScaleMode merken
    oScaleMode = .ScaleMode
 
    ' ScaleMode auf Pixel setzen
    .ScaleMode = vbPixels
 
    ' Sicherstellen, das AutoRedraw=True ist
    oAutoRedraw = .AutoRedraw
    .AutoRedraw = True
 
    For X = 1 To .ScaleWidth
      For Y = 1 To .ScaleHeight
        Color1 = .Point(X, Y)
        Color2 = .Point(X + 1, Y)
        Bildfeld.PSet (X, Y), Durchschnitt(Color1, Color2)
    Next Y, X
 
    ' ursprünglichen Einstellungen wiederherstellen
    .ScaleMode = oScaleMode
    .AutoRedraw = oAutoRedraw
  End With
End Sub
 
' Blau-Anteil einer Farbe
Private Function ColorBlue(ByVal Color As Long) As Integer
  ColorBlue = Color \ &H10000 And &HFF&
End Function
 
' Rot-Anteil einer Farbe
Private Function ColorRed(ByVal Color As Long) As Integer
  ColorRed = Color And &HFF&
End Function
 
' Grün-Anteil einer Farbe
Private Function ColorGreen(ByVal Color As Long) As Integer
  ColorGreen = Color \ &H100& And &HFF&
End Function
 
' Berechnet den neuen Farbwert zweier Farbwerten
' Hierbei werden die RGB-Anteile der beiden Farben
' zusammenaddiert und anschiessend durch 2 geteilt
Private Function Durchschnitt(Color1 As Long, _
  Color2 As Long) As Long
 
  Dim R As Long
  Dim G As Long
  Dim B As Long
 
  R = (ColorRed(Color1) + ColorRed(Color2)) / 2
  G = (ColorGreen(Color1) + ColorGreen(Color2)) / 2
  B = (ColorBlue(Color1) + ColorBlue(Color1)) / 2
 
  Durchschnitt = RGB(R, G, B)
End Function

Private Sub Command1_Click()
  Verwischen Picture1
End Sub

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.