Drag & Drop im ListView-Control Dieses Beispiel zeigt, wie sich Zeilen innerhalb des ListView per Drag & Drop verschieben lassen.
Autor:   Norbert Seltmann	Bewertung:	Views:  28.061
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Das nachfolgende Beispiel zeigt, wie sich ein ListView-Eintrag (gesamte Zeile inkl. aller Spalten) per Drag & Drop verschieben lässt.

Vorgehensweise:
Zunächst sucht man sich ein passendes Drag-Symbol aus, d.h. anstelle des normalen Mauszeigers soll beim Drag & Drop Vorgang ein spezielles Symbol angezeigt werden, so daß sofort erkennbar ist, daß eine Drag & Drop Aktion gestartet wird. Hierzu eignen sich folgende Symbole, die bei der Installation von Visual Basic i.a.R. installiert wurden: DRAGMOVE.CUR, DRAGCOPY.CUR oder DRAGLINK.CUR. Zu finden sind diese Symbole unter \Visual Studio\Common\Graphics\Cursor.

Der Drag-Vorgang soll beim Klicken auf einen Eintrag und gleichzeitiges Bewegen der Maus gestartet werden. Damit wir später wissen, welcher Eintrag verschoben werden soll, merken wir uns diesen in einer formglobalen Variable:

Option Explicit
 
' Eintrag, der verschoben wird
Private oDragItem As ListItem

' aktuelles ListView-Element "merken"
Private Sub ListView1_MouseDown(Button As Integer, _
  Shift As Integer, x As Single, y As Single)
 
  If Button = vbLeftButton And oDragItem Is Nothing Then
    Set oDragItem = ListView1.HitTest(x, y)
  End If
End Sub

' Drag-Vorgang starten
Private Sub ListView1_MouseMove(Button As Integer, _
  Shift As Integer, x As Single, y As Single)
 
  If Button = vbLeftButton And Not (oDragItem Is Nothing) Then
    ListView1.Drag vbBeginDrag
  End If
End Sub

Sobald wir den Dragvorgang mittels ListView1.Drag vbBeginDrag starten, verwandelt sich der Mauszeiger in das in DragIcon festgelegte Symbol.

Wird die Maustaste nach gestarteter Dragaktion über einen anderen ListView-Eintrag losgelassen, wird das DragDrop Ereignis ausgelöst. Hier muss nun der ursprüngliche ListView-Eintrag an die aktuelle Position verschoben werden.

' Zeile verschieben
Private Sub ListView1_DragDrop(Source As Control, _
  x As Single, y As Single)
 
  Dim oItem As ListItem
  Dim oNewItem As ListItem
  Dim iCol As Integer
  Dim sKey As String
  Dim iIndex As Integer
 
  With ListView1
    ' Verschieben möglich?
    Set oItem = .HitTest(x, y)
    If Not (oItem Is Nothing) And TypeOf Source Is ListView And _
      Not (oDragItem Is Nothing) Then
 
      ' Neue Zeile einfügen und Text der 1. Spalte übertragen
      sKey = oDragItem.Key
      iIndex = oItem.Index
      If iIndex > oDragItem.Index Then iIndex = iIndex + 1
      Set oNewItem = ListView1.ListItems.Add(iIndex, , _
        oDragItem.Text)
 
      ' SubItems übertragen (Spalten 2-n)
      For iCol = 1 To .ColumnHeaders.Count - 1
        oNewItem.SubItems(iCol) = oDragItem.SubItems(iCol)
      Next iCol
 
      ' Eintrag löschen
      Source.ListItems.Remove oDragItem.Key
 
      ' Key übertragen
      oNewItem.Key = sKey
      Set oDragItem = Nothing
    End If
  End With
End Sub

' Drag-Vorgang beendet
Private Sub ListView1_MouseUp(Button As Integer, _
  Shift As Integer, x As Single, y As Single)
 
  Set oDragItem = Nothing
End Sub

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.