vb@rchiv · Tipps & Tricks · System-Namen gedrückter Tasten ermitteln

Rubrik: Maus & Tastatur · Tastatursteuerung | VB-Versionen: VB4, VB5, VB6

09.06.02

System-Namen gedrückter Tasten ermitteln Ein Beispiel, wie sich der System-Name einer gedrückten Taste ermitteln lässt.
Autor: LonelySuicide666	Bewertung:	Views: 21.224
www.vbapihelpline.de	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Dieses Beispiel zeigt, wie Sie ohne großen Aufwand den Tastennamen einer Tastaturtaste ermitteln, wobei die systemeigenen Tastennamen verwendet werden.

Erstellen Sie ein neues Projekt und fügen nachfolgenden Code in den Codeteil der Form ein.

' benötigte API-Deklarationen
Private Declare Function GetKeyNameText Lib "user32" _
  Alias "GetKeyNameTextA" ( _
  ByVal lParam As Long, _
  ByVal lpBuffer As String, _
  ByVal nSize As Long) As Long
 
Private Declare Function MapVirtualKey Lib "user32" _
  Alias "MapVirtualKeyA" ( _
  ByVal wCode As Long, _
  ByVal wMapType As Long) As Long
 
Private Declare Sub CopyMemory Lib "kernel32" _
  Alias "RtlMoveMemory" ( _
  Destination As Any, _
  Source As Any, _
  ByVal Length As Long)
 
Private DownKeys(256) As Byte

Wird nun eine Taste gedrückt, soll der systemeigene Tastenname auf der Form ausgegeben werden.

Private Sub Form_Load()
  ' Alle Tastaturereignisse sollen die Form erreichen
  Me.KeyPreview = True
End Sub
 
' Taste wird niedergedrückt
Private Sub Form_KeyDown(KeyCode As Integer, _
  Shift As Integer)
 
  DownKeys(KeyCode) = DownKeys(KeyCode) Xor KeyCode
  Call ShowDownKeys
End Sub
 
' Taste wird losgelassen
Private Sub Form_KeyUp(KeyCode As Integer, _
  Shift As Integer)
 
  DownKeys(KeyCode) = 0
  Call ShowDownKeys
End Sub

' Ermitteln einer Tastenbezeichnung anhand einer
' VBKey-Konstante (Keycode)
Private Function GetKeyText(ByVal KeyCode As KeyCodeConstants) As String
  Dim ScanCodeLng As Long
  Dim ScanCodeByte(3) As Byte
  Dim lParamLng As Long
  Dim lParamByte(3) As Byte
  Dim TmpBuffer As String * 256
 
  ' Scancode ermitteln (tastaturspezifische Tasten-ID)
  ScanCodeLng = MapVirtualKey(KeyCode, 0)
  CopyMemory ScanCodeByte(0), ScanCodeLng, 4
 
  ' lParam zusammenbauen
  lParamByte(0) = 1
  lParamByte(2) = ScanCodeByte(0)
  CopyMemory lParamLng, lParamByte(0), 4
 
  ' Text der Taste ermitteln
   Call GetKeyNameText(lParamLng, TmpBuffer, Len(TmpBuffer))
 
   GetKeyText = StrConv(Left(TmpBuffer, _
     InStr(1, TmpBuffer, vbNullChar) - 1), vbProperCase)
End Function

' alle gedrückten Tasten in einem Label ausgeben
Private Sub ShowDownKeys()
  Dim TmpStr As String
  Dim i As Integer
 
  ' Tastendruck zusammenstellen
  For i = 0 To UBound(DownKeys)
    If DownKeys(i) <> 0 Then
      TmpStr = TmpStr & GetKeyText(DownKeys(i)) & " + "
    End If
  Next i
 
  ' String kürzen
  If TmpStr <> "" Then _
    TmpStr = Left$(TmpStr, Len(TmpStr) - 3)
 
  ' Tastendruck ausgeben
  With Me
    .Cls
    .CurrentX = 5 * Screen.TwipsPerPixelX
    .CurrentY = 5 * Screen.TwipsPerPixelY
    Me.Print TmpStr
  End With
End Sub