vb@rchiv · Tipps & Tricks · ADO: Erhöhen der Recordsetleistung

Rubrik: Datenbanken · ADO | VB-Versionen: VB5, VB6

01.07.02

ADO: Erhöhen der Recordsetleistung Durch den Einsatz von Variant-Arrays lässt sich das Einfügen neuer Datensätze um bis zu 400 Prozent steigern!
Autor: Daniel Petri	Bewertung:	Views: 32.440
www.beatsoft.de	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Sie können die Einfügeleistung von ADO erheblich steigern, indem Sie Einfügungen mit Hilfe von Variant-Arrays durchführen, anstatt Feld für Feld auf die Field Value-Eigenschaft zuzugeifen. Mit Hilfe dieser Technik können Leistungssteigerungen von bis zu 400 Prozent erreicht werden.

Zur Veranschaulichung haben wir Ihnen folgendes Testprogramm zusammengestellt. Erstellen Sie ein neues Projekt und setzen einen Verweis auf die Microsoft ActiveX Data Objects 2.5 Library. Platzieren Sie anschließend einen CommandButton (Command1) auf die Form und fügen dann nachfolgenden Code ein.

Option Explicit
 
' API zur Zeitmessung
Private Declare Function GetTickCount Lib "kernel32.dll" () As Long

' Test: Einfügen von Daten via FIELD-Zuweisung im
' Vergleich zum Einfügen via Variant-ARRAY
Public Sub ADOFastInsert()
  Dim rs As ADODB.Recordset
  Dim sngStartTimer As Single
  Dim i As Long
  Dim j As Long
  Dim arrRecords() As Variant
  Dim arrFieldList() As Variant
 
  ' 1000 Datensätze á 20 Felder
  Const RECORD_COUNT = 1000
  Const FIELD_COUNT = 20
 
  ' Erstellen des Recordsets
  Set rs = New ADODB.Recordset
  ReDim arrFieldList(0 To FIELD_COUNT - 1)
 
  ' Felder erstellen
  For i = 1 To FIELD_COUNT
    rs.Fields.Append "f" & i, adChar, 10
    arrFieldList(i - 1) = "f" & i
  Next i
 
  ' Recordset öffnen
  rs.Open
 
  ' Herkömmliches Verfahren:
  ' Einfügen via FIELD-Zuweisung
  sngStartTimer = GetTickCount()
  With rs
    For i = 1 To RECORD_COUNT
      .AddNew
      For j = 0 To FIELD_COUNT - 1
        .Fields(j).Value = "xxxxxxxxxx"
      Next j
      .Update
    Next i
    MsgBox "Benötigte Zeit für das herkömmlich " & _
      "Einfügeverfahren: " & _
      CStr(GetTickCount - sngStartTimer) & " MSek"
  End With
 
  ' Zum Vergleich: Einfügen der Daten via Variant-Array
  sngStartTimer = GetTickCount()
  With rs
    For i = 1 To RECORD_COUNT
      ReDim arrRecords(0 To FIELD_COUNT - 1)
      For j = 0 To FIELD_COUNT - 1
        arrRecords(j) = "xxxxxxxxxx"
      Next j
      .AddNew arrFieldList, arrRecords
    Next i
    MsgBox "Benötigte Zeit für das Einfügeverfahren " & _
      "via Variant-Array: " & _
      CStr(GetTickCount - sngStartTimer) & " MSek"
  End With
 
  ' Recordset schließen
  rs.Close
End Sub

' Testen
Private Sub Command1_Click()
  ADOFastInsert
End Sub