Feldgröße nachträglich ändern (DAO) Eine universelle Prozedur, mit der sich die Feldgröße eines Datenbankfeldes nachträglich verändern lässt.
Autor:   Dieter Otter	Bewertung:	Views:  19.963
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Standen Sie auch schon einmal vor dem Problem, dass Sie ein Feld einer Datenbank-Tabelle nachträglich vergrößern mussten? Hierbei sollten die bisherigen Feldinhalte natürlich nicht verloren gehen.

Leider lässt sich die Size-Eigenschaft eines Datenbankfeldes aber nachträglich nicht mehr ändern, so dass man gezwungen ist, ist ein neues Feld zu erstellen, die bisherigen Feldinhalte umzukopieren und das ursprüngliche Feld dann zu löschen.

Die Schritte hierfür sind im einzelnen:

1. neues Feld anlegen (irgendein Name) mit der neuen Feldlänge
2. Tabelle durchlaufen und Feldinhalte in das neue Feld schreiben
3. altes Feld löschen
4. neues Feld in alted Feld umbenennen
5. OrdinalPosition entsprechend zurücksetzen

Nachfolgende Prozedur erledigt genau diese Schritte, so dass ein Feld in Zukunft mit nur einem einzigen Prozeduraufruf nachträglich vergrößert werden kann.

' Feldgröße nachträglich ändern
Public Sub dbField_ChangeSize(Db As Database, _
  ByVal sTable As String, ByVal sField As String, _
  ByVal iNewSize As Integer)
 
  Dim oField As New Field
  Dim Rs As Recordset
  Dim iPosition As Integer
 
  With Db.TableDefs(sTable)
    ' temporäres Feld erstellen
    oField.Name = sField + "_tmp"
    oField.Type = dbText
    oField.AllowZeroLength = True
    oField.Size = iNewSize
    .Fields.Append oField
 
    ' Tabelle öffnen und alten Feldinhalt ins
    ' neue temporäre Feld speichern
    Set Rs = Db.OpenRecordset("SELECT " + sField + ", " + _
      sField + "_tmp FROM " + sTable)
    If Rs.RecordCount > 0 Then
      Do Until Rs.EOF
        Rs.Edit
        Rs(1) = Rs(0)
        Rs.Update
        Rs.MoveNext
      Loop
    End If
    Rs.Close
    Set Rs = Nothing
 
    ' OrdinalPosition merken
    iPosition = .Fields(sField).OrdinalPosition
 
    ' altes Feld löschen
    .Fields.Delete sField
 
    ' neues temporäre Feld umbenennen
    .Fields(sField + "_tmp").Name = sField
 
    ' Ordinalposition wiederherstellen
    .Fields(sField).OrdinalPosition = iPosition
  End With
End Sub

Beispiel für den Aufruf:

Dim Db As Database
 
Set Db = DBEngine.OpenDatabase("Datenbank.mdb")
dbField_ChangeSize Db, "Adressen", "Name", 50

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.