vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Oberfläche · Sonstiges   |   VB-Versionen: VB4, VB5, VB603.12.02
Farbauswahl-Dialog per API

Um den Windows-Farbauswahl-Dialog zu verwenden, braucht nicht unbedingt das CommonDialog-Control - es geht auch per API.

Autor:   Dieter OtterBewertung:  Views:  15.782 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Um den Windows-Standard-Dialog zur Farbauswahl in seiner VB-Anwendung zu verwenden, braucht man nicht unbedingt auf das CommonDialog-Control (COMDLG32.OCX) zurückzugreifen. Wie jeden Windows-Standard-Dialog lässt sich auch dieser Dialog über das Windows-API aufrufen.

Fügen Sie hierzu nachfolgenden Code in Ihr Projekt ein:

' zunächst die benötigten API-Deklarationen
Private Declare Function ChooseColor Lib "comdlg32.dll" _
  Alias "ChooseColorA" ( _
  pChoosecolor As LPCHOOSECOLOR) As Long
 
Private Type LPCHOOSECOLOR
  lStructSize As Long
  hWnd As Long
  hInstance As Long
  rgbResult As Long
  lpCustColors As String
  Flags As Long
  lCustData As Long
  lpfnHook As Long
  lpTemplateName As String
End Type
 
Private Const CC_SOLIDCOLOR = &H80
Private Const CC_FULLOPEN = &H2
' Farb-Auswahl-Dialog anzeigen
Public Function ShowColorDlg(ByVal hWnd As Long, _
  Optional ByVal bExtColors As Boolean) As Long
 
  Dim nResult As Long
  Dim pColor As LPCHOOSECOLOR
  Dim nCustColor(16) As Long
 
  With pColor
    .lStructSize = Len(pColor)
    .hWnd = hWnd
    .hInstance = App.hInstance
 
    ' Flags setzen!
    .Flags = CC_SOLIDCOLOR
    If bExtColors Then .Flags = .Flags Or CC_FULLOPEN
 
    ' Standard-Farben
    .lpCustColors = String$(16 * 4, 0)
 
    ' Dialog anzeigen
    nResult = ChooseColor(pColor)
    If nResult <> 0 Then
      ' Farb-Rückgabewert
      ShowColorDlg = .rgbResult
    Else
      ' Abbrechen wurde gewählt
      ShowColorDlg = -1
    End If
  End With
End Function

Aufruf der Funktion:

Dim nColor As Long
 
nColor = ShowColorDlg(Me.hWnd)
If nColor <> - 1 Then
  Me.BackColor = nColor
End If

Beim genaueren Betrachten der ShowColorDlg-Funktion fällt auf, dass es auch noch einen zweiten Parameter gibt: bExtColor. Über diesen zweiten booleaschen-Parameter lässt sich festlegen, ob die Standard-Farbauswahl oder die erweiterte Farbauswahl angezeigt werden soll.

' erweiterer Farbauswahl-Dialog
nColor = ShowColorDlg(Me.hWnd, True)



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2019 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.