Buttoneigenschaft im DataGrid nutzen Dieser Tipp soll Ihnen als Anregung dazu dienen, wie man den Button eines DataGrids nutze könnte.
Autor:   Oliver Greiner	Bewertung:	Views:  19.463
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Die MSDN sagt nicht sehr viel über die Buttoneigenschaft des DataGrids aus. Der Button, der vom DataGrid zur Verfügung gestellt wird reagiert auf ein Klickereignis. Was letztendlich dann passiert bleibt der Kreativität des Entwicklers überlassen. Da im Forum danach gefragt wurde, soll dieses kleine Beispiel dazu dienen, wie man den Button nutzen könnte.

Alles, was Sie hierzu benötigen ist eigentlich nur das DataGrid und eine ListBox. Die ListBox ziehen Sie auf die Form und setzen die Visible-Eigenschaft auf False. Nun Legen Sie die Buttoneigenschaft für eine Spalte auf True.

Im Klickereignis auf den Button, positionieren Sie die ListBox und lassen sie erscheinen.

Sorgen Sie aber dafür, dass sich Daten im DataGrid befinden, da es sonst zum Fehler 'Ungültige Zeilennummer' kommt.

Option Explicit
 
' Hier merken wir uns die Spalte
Private nColIndex As Long

Private Sub DataGrid1_ButtonClick(ByVal ColIndex As Integer)
  ' Wenn sich keine Daten im DataGrid befinden steht
  ' die Row eigenschaft auf -1.
  With DataGrid1
    If .Row <> -1 Then
      ' Die Breite der ListBox an die Breite der
      ' Spalte anpassen und die Position ausrichten
      nColIndex = ColIndex
      List1.Left = .Left + .Columns(ColIndex).Left
      List1.Width = .Columns(ColIndex).Width
 
      ' ListBox unter die ausgewählte Zeile setzen
      List1.Top = .Top + .RowTop(.Row) + (.RowHeight)
 
      ' Listbox einblenden
      List1.Visible = True
    End If
  End With
End Sub

Eigentlich ganz easy, eine DropDown Liste á la ComboBox für jede Zeile

Falls in einen anderen Bereich des DataGrids gelickt wird, soll die Listbox wieder verschwinden.

Private Sub DataGrid1_Click()
  ' Listbox ausblenden
  List1.Visible = False
End Sub

Zusätzlich muss das Scrollereignis noch ausgewertet werden, da dieses nicht auf das Klickereignis des DataGrids reagiert. Wenn man das nicht tun würde, würde die ListBox stehenbleiben und die Spalte, wo sie eigendlich hingehört, ist verschwunden.

' Falls der sichtbare Bereich verschwindet, die
' ListBox mit verschwinden lassen, da sie sonst unter
' der falschen Spalte steht.
Private Sub DataGrid1_Scroll(Cancel As Integer)
  With DataGrid1
    List1.Visible = False
  End With
End Sub

Bei Auswahl eines Eintrags aus der ListBox, sollen diese in die aktuelle Datenzelle geschrieben werden:

Private Sub List1_Click()
  With List1
    ' Auswahl in die Datenzelle übernehmen...
    DataGrid1.Columns(nColIndex).Text = .Text
 
    ' ... und die ListBox ausblenden.
    .Visible = False
  End With
End Sub

Die ListBox selbst können Sie im Form_Load Ereignis mit Daten füllen oder auch direkt im ButtonClick-Ereignis des DataGrid-Controls.
 

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.