vb@rchiv · Tipps & Tricks · MsgBox beliebig positionieren

Rubrik: Oberfläche · MessageBox | VB-Versionen: VB4, VB5, VB6

13.03.03

MsgBox beliebig positionieren Mit einem kleinen Trick lässt sich eine MessageBox beliebig am Bildschirm positionieren.
Autor: Dieter Otter	Bewertung:	Views: 29.666
www.tools4vb.de	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Die Windows-MessageBox gehört wohl mit den zu den am häufigsten verwendeten Dialogfenstern. Deshalb besitzt VisualBasic auch von Haus aus die MsgBox-Funktion. Leider wird die MessageBox aber immer in der Bildschirmmitte angezeigt. Soll die MessageBox an einer beliebigen Position auf dem Desktop platziert werden, müssen wir wieder einmal in die API-Trickkiste greifen

Statt der "normalen" MsgBox-Funktion von VB verwenden wir die API MessageBox-Funktion. Der Vorteil der API-Variante ist der, dass die Windows-Messages parallel weiterlaufen, während die MsgBox von VB dies nicht zulässt. Auf diese Weise kann man dann über einen Timer das Handle der MessageBox ermitteln und diese dann mit Hilfe der SetWindowPos-Funktion beliebig auf dem Desktop positionieren.

Für das nachfolgende Beispiel benötigen wir eine Form, ein Timer-Control, sowie einen Command-Button.

Option Explicit
 
' Benötigte API-Deklarationen
Private Declare Function MessageBox Lib "user32" _
  Alias "MessageBoxA" ( _
  ByVal hwnd As Long, _
  ByVal lpText As String, _
  ByVal lpCaption As String, _
  ByVal wType As Long) As Long
 
Private Declare Function GetActiveWindow Lib "user32" () As Long
 
Private Declare Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal hWndInsertAfter As Long, _
  ByVal x As Long, _
  ByVal y As Long, _
  ByVal cx As Long, _
  ByVal cy As Long, _
  ByVal wFlags As Long) As Long
 
Private Const SWP_NOSIZE = &H1

Private Sub Command1_Click()  
 
  ' Timer starten
  Timer1.Interval = 50
  Timer1.Enabled = True
 
  ' MsgBox anzeigen
  MessageBox Me.hwnd, "Test", "MsgBox", vbOKOnly
End Sub

Private Sub Timer1_Timer()
  Dim nHWnd As Long
  Dim x As Long
  Dim y As Long
 
  ' Handle der MsgBox ermitteln
  DoEvents
  nHWnd = GetActiveWindow()
 
  ' MsgBox positionieren
  x = 0: y = 0
  SetWindowPos nHWnd, Me.hwnd, x, y, 0, 0, SWP_NOSIZE
  Timer1.Enabled = False
End Sub