Verknüpfung erstellen mit dem WScript-Objekt Sie wollen eine beliebige Verknüpfung erstellen? - Dann schauen Sie sich diese Funktion an!
Autor:   David Horch	Bewertung:	Views:  22.062
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Tja, ich brauchte mal eine Verknüpfung und habe dann einfach das WScript-Objekt benutzt. Hiermit geht es viel besser, eine Verknüpfung zu erstellen, als mit anderen bisher bekannten Mitteln.

Lange Rede, kurzer Sinn:
Die Funktion CreateShortCut benötigt folgende Werte:

• TargetPath: zu verknüpfende Datei / Programm
• ShortcutPath: Pfad & Dateiname der Verknüpfung, Extension = .lnk
• WorkingDirectory: Arbeitsverzeichnis der zu verknüpfenden Datei
• Parameter: Optional. Parameter, der mit dem Programm gestartet wird. Beispiel: "C:\Windows\Win.ini" oder "/s"
• IconLocation: Optional. Icon-Datei, ohne Angabe wird das Icon der zu verknüpfenden Datei genommen
• HotKey: Optional. Tastenkürzel

Ein Beispiel:
Der Windows-Editor soll auf dem Desktop mit dem Titel "Editor" verknüpt werden:

' Verzeichnisse bitte entsprechend anpassen
CreateShortCut "C:\Windows\Notepad.exe", _
  "C:\Windows\Desktop\Editor.lnk", "C:\Windows"

Und hier die Funktion:

Public Function CreateShortcut( _
  TargetPath As String, _
  ShortCutPath As String, _
  WorkingDirectory As String, _
  Optional IconLocation As String, _
  Optional Parameter As String, _
  Optional HotKey As String)
 
  Dim WshShell As Object
  Dim MyShortCut As Object
 
  ' Shell-Objekt erstellen
  Set WshShell = CreateObject("Wscript.Shell")
 
  ' ShortCut-Objekt erstellen
  Set MyShortCut = WshShell.CreateShortcut(ShortCutPath)
 
  Dim sIconLocation As String
  Dim sParameter As String
  Dim sHotKey As String
 
  ' Symbol (Icon-Datei)
  If IconLocation = Empty Then
    sIconLocation = TargetPath
  Else
    sIconLocation = IconLocation
  End If
 
  ' Parameter
  If Parameter = Empty Then
    sParameter = ""
  Else
    sParameter = Parameter
  End If
 
  ' HotKey
  If HotKey = Empty Then
    sHotKey = ""
  Else
    sHotKey = HotKey
  End If
 
  ' Verknüpfungs-Eigenschaften
  With MyShortCut
    .TargetPath = TargetPath
    .IconLocation = sIconLocation
    .Arguments = sParameter
    .Description = ""
    .WindowStyle = 1
    .WorkingDirectory = WorkingDirectory
    .HotKey = sHotKey
    .Save
  End With
 
  ' Objekte zerstören
  Set MyShortCut = Nothing
  Set WshShell = Nothing
End Function

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.