vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Grafik und Font · Grafische Effekte   |   VB-Versionen: VB4, VB5, VB615.12.03
Bild drehen mit PlgBlt-API (GES)

Superschneller Code zum horizontalen oder vertikalen Drehen/Spiegeln von Bildern inkl. Zoom-Funktion.

Autor:   Guido EisenbeisBewertung:  Views:  34.542 
ohne HomepageSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Dieser Code bietet die Möglichkeiten, ein Bild horizontal und vertikal zu drehen/spiegeln und auch noch zu zoomen. Und das mit einer unglaublichen Geschwindigkeit, die sich auch schon bei "normal"-grossen Bildern bemerkbar macht! Der Code arbeitet so ressourcenschonend, dass der Prozessor fast gar nichts mitbekommt.

Der Original-Source (Autor: Daniel Aue) stammt von http://www.activevb.de und kann frei verwendet werden. Für eventuelle Schäden wird nicht gehaftet.

Die oben genannte hervorragende Arbeit wurde mit nachfolgendem Code so modifiziert, dass eine einfach und übersichtlich zu handhabende Prozedur entstanden ist. Sogar die Einbindung in bestehende Projekte ist problemlos möglich. Eine vorhandene PictureBox kann einfach übergeben werden.

Benötigt werden 2 PictureBoxes. Voreinstellungen sind nicht nötig, da diese vom Code übernommen werden. Einfacher geht's nicht.

Option Explicit
 
' Benötigte API-Funktionen
Private Declare Function PlgBlt Lib "gdi32.dll" ( _
  ByVal hdcDest As Long, _
  lpPoint As POINTAPI, _
  ByVal hdcSrc As Long, _
  ByVal nXSrc As Long, _
  ByVal nYSrc As Long, _
  ByVal nWidth As Long, _
  ByVal nHeight As Long, _
  ByVal hbmMask As Long, _
  ByVal xMask As Long, _
  ByVal yMask As Long) As Long
 
Private Type POINTAPI
  x As Long
  y As Long
End Type
 
Private Const pi180 = 3.14159265358979 / 180
Private PtList(2) As POINTAPI
' Aufruf-Beispiele:
' 
' Private Sub Form_Load()
'    ' Bild laden
'    picQuelle.Picture = LoadPicture(App.Path & "\Test.jpg")
'    ' Bild ohne Drehung darstellen
'    Call BildDrehen(picQuelle, picZiel)
' End Sub
 
'    ' Bild im Uhrzeigersinn um 90° drehen
'    Call BildDrehen(picQuelle, picZiel, 90)
 
'    ' Bild horizontal spiegeln
'    Call BildDrehen(picQuelle, picZiel, , , 180)
 
'    ' Bild vertikal spiegeln
'    Call BildDrehen(picQuelle, picZiel, , , , 180)
 
' -------------------------------------------------------------------
' Mögliche Werte:
'     DrehWinkel  -360 bis 360
' horzDrehWinkel  -180 bis 180 (180 = Spiegelung)
' vertDrehWinkel  -180 bis 180 (180 = Spiegelung)
' -------------------------------------------------------------------
 
Public Sub BildDrehen(ByVal picSource As PictureBox, ByVal picDest As PictureBox, _
  Optional ByVal DrehWinkel As Long = 0, _
  Optional ByVal intZoom As Integer = 46, _
  Optional ByVal horzDrehWinkel As Long = 0, _
  Optional ByVal vertDrehWinkel As Long = 0)
 
  Dim i As Integer
  Dim NewX As Double, NewY As Double
  Dim SinAng1 As Double, CosAng1 As Double
  Dim SinAng2 As Double, SinAng3 As Double
  Dim dblZoom As Double
 
  With picSource
    .Visible = False
    .ScaleMode = vbPixels
    .AutoRedraw = True
    .AutoSize = True
    picDest.ScaleMode = vbPixels
    picDest.AutoRedraw = True
 
    ' Punktliste zurücksetzen:
    PtList(0).x = -(.ScaleWidth / 2)
    PtList(0).y = -(.ScaleHeight / 2)
    PtList(1).x = (.ScaleWidth / 2)
    PtList(1).y = -(.ScaleHeight / 2)
    PtList(2).x = -(.ScaleWidth / 2)
    PtList(2).y = (.ScaleHeight / 2)
 
    ' Variablen vorberechnen:
    dblZoom = Tan(intZoom * pi180)
    SinAng1 = Sin((DrehWinkel + 90) * pi180)
    CosAng1 = Cos((DrehWinkel + 90) * pi180)
    SinAng2 = Sin((horzDrehWinkel + 90) * pi180) * dblZoom
    SinAng3 = Sin((vertDrehWinkel + 90) * pi180) * dblZoom
 
    ' Punkte transformieren:
    For i = 0 To 2
      NewX = (PtList(i).x * SinAng1 + PtList(i).y * CosAng1) * SinAng2
      NewY = (PtList(i).y * SinAng1 - PtList(i).x * CosAng1) * SinAng3
      PtList(i).x = NewX + (picDest.ScaleWidth / 2)
      PtList(i).y = NewY + (picDest.ScaleHeight / 2)
    Next i
 
    ' alte Darstellung löschen
    picDest.Cls
    picDest.Picture = Nothing
 
    ' neue Darstellung zeichnen:
    Call PlgBlt(picDest.hDC, PtList(0), .hDC, 0, 0, _
      .ScaleWidth, .ScaleHeight, 0, 0, 0)
 
    ' und in die Anzeige PicBox übernehmen:
    picDest.Picture = picDest.Image
  End With
End Sub

Anwendungsbeispiel:
Starten Sie ein neues Projekt und fügen obigen Code in ein Modul ein. Platzieren Sie auf die Form1 2 PictureBox-Controls: picOriginalBild und picAnzeigeBox. Weiterhin werden noch 3 CommandButtons benötigt (Command1, Command2 und Command3), eine TextBox (Text1), sowie eine horizontale Scrollbar (HScroll1).

Fügen Sie nachfolgenden Code in das Codefenster der Form1 ein:

Option Explicit
 
Private Sub Form_Load()
  ' Bild laden
  picOriginalBild.Picture = LoadPicture( _
    App.Path & "\IgrnedeinBild.JPG")
 
  ' Bild ohne Drehung darstellen
  Call BildDrehen(picOriginalBild, picAnzeigeBox)
 
  ' Zoombereich festlegen
  With HScroll1
    .Min = 46
    .Max = 86
    .SmallChange = 1
    .LargeChange = 1
  End With
End Sub
Private Sub Command1_Click()
  ' Bild drehen
  Call BildDrehen(picOriginalBild, picAnzeigeBox, Text1.Text)
End Sub
Private Sub Command2_Click()
  ' Bild horizontal spiegeln
  Call BildDrehen(picOriginalBild, picAnzeigeBox, , , 180)
End Sub
Private Sub Command3_Click()
  ' Bild vertikal spiegeln
  Call BildDrehen(picOriginalBild, picAnzeigeBox, , , , 180)
End Sub
Private Sub HScroll1_Change()
  ' Bild zoomen
  Call BildDrehen(picOriginalBild, picAnzeigeBox, , _
    HScroll1.Value)
End Sub



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.