vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
vb@rchiv Offline-Reader - exklusiv auf der vb@rchiv CD Vol.4  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2018
 
zurück
Rubrik: System/Windows · Computer/Benutzer/Ländereinstellungen   |   VB-Versionen: VB625.08.08
Zahlenformat systemweit ändern

Diese Funktion ermöglicht das Ändern des im System eingestellte Zahlen- und Währungsformats.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  13.058 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Mit nachfolgender Funktion lässt sich das im System eingestellte Zahlen- und Währungsformat (Tausender- und Dezimaltrennzeichen) neu festlegen - entweder für den aktuell angemeldeten Benutzer oder auf Wunsch auch auf alle Benutzer.

' benötigte API-Deklarationen
Private Declare Function GetSystemDefaultLCID Lib "kernel32" () As Long
 
Private Declare Function GetUserDefaultLCID Lib "kernel32" () As Long
 
Private Declare Function SetLocaleInfo Lib "kernel32" _
  Alias "SetLocaleInfoA" ( _
  ByVal Locale As Long, _
  ByVal LCType As Long, _
  ByVal lpLCData As String) As Long
 
Private Declare Function PostMessage Lib "user32" _
  Alias "PostMessageA" ( _
  ByVal hWnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Long) As Long
 
Private Const LOCALE_SMONDECIMALSEP = &H16
Private Const LOCALE_SDECIMAL = &HE
Private Const LOCALE_SMONTHOUSANDSEP = &H17
Private Const LOCALE_STHOUSAND = &HF
 
Private Const WM_SETTINGCHANGE = &H1A
Private Const HWND_BROADCAST = &HFFFF&
Public Function SetNewNumberFormat(ByVal sDecChar As String, _
  Optional ByVal sGroupChar As String = "", _
  Optional ByVal bAllUser As Boolean = True) As Boolean
 
  Dim nLCID As Long
  Dim bResult As Boolean
 
  If bAllUser Then
    ' systemweite Änderung für alle Benutzer
    nLCID = GetSystemDefaultLCID()
  Else
    ' Änderung nur für den aktuell angemeldeten Benutzer
    nLCID = GetUserDefaultLCID()
  End If
 
  ' Neues Währungsformat setzen
  bResult = (SetLocaleInfo(nLCID, LOCALE_SMONDECIMALSEP, sDecChar) <> 0)
  bResult = (SetLocaleInfo(nLCID, LOCALE_SMONTHOUSANDSEP, sGroupChar) <> 0)
 
  ' Neues Zahlenformat setzen
  bResult = (SetLocaleInfo(nLCID, LOCALE_SDECIMAL, sDecChar) <> 0)
  bResult = (SetLocaleInfo(nLCID, LOCALE_STHOUSAND, sGroupChar) <> 0)
  If bResult Then
    ' System über die Änderung benachrichtigen
    PostMessage HWND_BROADCAST, WM_SETTINGCHANGE, 0, 0
  End If
 
  SetNewNumberFormat = bResult
End Function

Beispielaufruf:

' Punkt als Tausenderzeichen, und Komma als Dezimalzeichen 
' für den aktuellen Benutzer festlegen
If SetNewNumberFormat(",", ".", False) Then
  MsgBox "Zahlen- und Währungsformat wurden korrekt umgestellt"
Else
  MsgBox "Systemeinstellungen konnten nicht geändert werden." & vbCrLf & _
    "Ggf. hat der angemeldete Benutzer nicht genügend Rechte!"
End If

Dieser Tipp wurde bereits 13.058 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Aktuelle Diskussion anzeigen (3 Beiträge)

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2018 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel